包顶级
类public final dynamic class Date
继承Date Inheritance Object

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

Date 类表示日期和时间信息。Date 类的实例表示一个特定时间点，可以查询或修改该时间点的属性（如月、日、小时和秒）。Date 类用于检索相对于通用时间（格林尼治平均时，现称为通用时间或 UTC）或相对于本地时间（由运行 Flash Player 的操作系统上的本地时区设置决定）的日期和时间值。Date 类的方法不是静态方法，但仅应用于调用该方法时指定的单个 Date 对象。Date.UTC() 和 Date.parse() 方法为例外情况，它们属静态方法。

若要使用 Date 类，需使用 new 运算符构造一个 Date 实例。

ActionScript 3.0 增加了几个新的存取器属性，可用它们来替代用来访问或修改 Date 实例的许多 Date 类方法。ActionScript 3.0 中还包括 toString() 方法的几个新变种，其目的是遵从 ECMA-262 第三版，其中包括：Date.toLocaleString()、Date.toTimeString()、Date.toLocaleTimeString()、Date.toDateString() 和 Date.toLocaleDateString()。

若要计算相对时间或经过的时间，请参阅 flash.utils 包中的 getTimer() 方法。

查看示例

另请参见

flash.utils.getTimer()
Working with dates and times

公共属性
 属性定义方
 Inheritedconstructor : Object
对类对象或给定对象实例的构造函数的引用。
Object
  date : Number
按照本地时间返回 Date 对象所指定的表示月中某天的值（1 到 31 之间的一个整数）。
Date
  dateUTC : Number
按照通用时间 (UTC) 返回 Date 对象中的日期值（1 到 31 之间的一个整数）。
Date
  day : Number
[只读 (read-only)] 按照本地时间返回该 Date 所指定的星期值（0 代表星期日，1 代表星期一，依此类推）。
Date
  dayUTC : Number
[只读 (read-only)] 按照通用时间 (UTC) 返回该 Date 中的星期值（0 代表星期日，1 代表星期一，依此类推）。
Date
  fullYear : Number
按照本地时间返回 Date 对象中的完整年份值（一个 4 位数，例如 2000）。
Date
  fullYearUTC : Number
按照通用时间 (UTC) 返回 Date 对象中的四位数年份值。
Date
  hours : Number
按照本地时间返回 Date 对象中一天的小时值（0 到 23 之间的一个整数）。
Date
  hoursUTC : Number
按照通用时间 (UTC) 返回 Date 对象中一天的小时值（0 到 23 之间的一个整数）。
Date
  milliseconds : Number
按照本地时间返回 Date 对象中的毫秒值（0 到 999 之间的一个整数）部分。
Date
  millisecondsUTC : Number
按照通用时间 (UTC) 返回 Date 对象中的毫秒值（0 到 999 之间的一个整数）部分。
Date
  minutes : Number
按照本地时间返回 Date 对象的分钟值（0 到 59 之间的一个整数）部分。
Date
  minutesUTC : Number
按照通用时间 (UTC) 返回的 Date 对象的分钟值（0 到 59 之间的一个整数）部分。
Date
  month : Number
按照本地时间返回 Date 对象的月份值（0 代表一月，1 代表二月，依此类推）。
Date
  monthUTC : Number
按照通用时间 (UTC) 返回的 Date 对象的月份值（0 [1 月] 到 11 [12 月]）部分。
Date
 Inheritedprototype : Object
[静态] 对类或函数对象的原型对象的引用。
Object
  seconds : Number
按照本地时间返回 Date 对象的秒值（0 到 59 之间的一个整数）。
Date
  secondsUTC : Number
按照通用时间 (UTC) 返回的 Date 对象的秒值（0 到 59 之间的一个整数）部分。
Date
  time : Number
Date 对象中自 1970 年 1 月 1 日午夜（通用时间）以来的毫秒数。
Date
  timezoneOffset : Number
[只读 (read-only)] 计算机的本地时间和通用时间 (UTC) 之间的差值（以分钟为单位）。
Date
公共方法
 方法定义方
  
Date(yearOrTimevalue:Object, month:Number, date:Number = 1, hour:Number = 0, minute:Number = 0, second:Number = 0, millisecond:Number = 0)
构造一个新的 Date 对象，该对象将保存指定的日期和时间。
Date
  
getDate():Number
按照本地时间返回 Date 对象指定的月中某天的值（1 到 31 之间的一个整数）。
Date
  
getDay():Number
按照本地时间返回该 Date 所指定的星期值（0 代表星期日，1 代表星期一，依此类推）。
Date
  
getFullYear():Number
按照本地时间返回 Date 对象中的完整年份值（一个 4 位数，如 2000）。
Date
  
getHours():Number
按照本地时间返回 Date 对象中一天的小时值（0 到 23 之间的一个整数）部分。
Date
  
getMilliseconds():Number
按照本地时间返回 Date 对象中的毫秒值（0 到 999 之间的一个整数）部分。
Date
  
getMinutes():Number
按照本地时间返回 Date 对象中的分钟值（0 到 59 之间的一个整数）部分。
Date
  
getMonth():Number
按照本地时间返回该 Date 中的月份值（0 代表一月，1 代表二月，依此类推）部分。
Date
  
getSeconds():Number
按照本地时间返回 Date 对象中的秒值（0 到 59 之间的一个整数）部分。
Date
  
getTime():Number
按照通用时间返回 Date 对象中自 1970 年 1 月 1 日午夜以来的毫秒数。
Date
  
getTimezoneOffset():Number
以分钟为单位，返回计算机的本地时间和通用时间 (UTC) 之间的差值。
Date
  
getUTCDate():Number
按照通用时间 (UTC) 返回 Date 对象中表示月中某天的值（1 到 31 之间的一个整数）。
Date
  
getUTCDay():Number
按照通用时间 (UTC) 返回该 Date 中表示星期的值（0 代表星期日，1 代表星期一，依此类推）。
Date
  
getUTCFullYear():Number
按照通用时间 (UTC) 返回 Date 对象中的四位数年份值。
Date
  
getUTCHours():Number
按照通用时间 (UTC) 返回 Date 对象中一天的小时值（0 到 23 之间的一个整数）。
Date
  
getUTCMilliseconds():Number
按照通用时间 (UTC) 返回 Date 对象中的毫秒值（0 到 999 之间的一个整数）部分。
Date
  
getUTCMinutes():Number
按照通用时间 (UTC) 返回 Date 对象中的分钟值（0 到 59 之间的一个整数）部分。
Date
  
getUTCMonth():Number
按照通用时间 (UTC) 返回 Date 对象中的月份值（0 [一月] 到 11 [十二月]）部分。
Date
  
getUTCSeconds():Number
按照通用时间 (UTC) 返回 Date 对象中的秒值（0 到 59 之间的一个整数）部分。
Date
 Inherited
hasOwnProperty(name:String):Boolean
指示对象是否已经定义了指定的属性。
Object
 Inherited
isPrototypeOf(theClass:Object):Boolean
指示 Object 类的实例是否在指定为参数的对象的原型链中。
Object
  
parse(date:String):Number
[静态] 按照 UTC 将表示日期的字符串转换为一个数字，它等于自 1970 年 1 月 1 日起已经过的毫秒数。
Date
 Inherited
propertyIsEnumerable(name:String):Boolean
指示指定的属性是否存在、是否可枚举。
Object
  
setDate(day:Number):Number
按照本地时间设置月中的某天，并以毫秒为单位返回新时间。
Date
  
setFullYear(year:Number, month:Number, day:Number):Number
按照本地时间设置年份值，并以毫秒为单位返回新时间。
Date
  
setHours(hour:Number, minute:Number, second:Number, millisecond:Number):Number
按照本地时间设置小时值，并以毫秒为单位返回新时间。
Date
  
setMilliseconds(millisecond:Number):Number
按照本地时间设置毫秒值，并以毫秒为单位返回新时间。
Date
  
setMinutes(minute:Number, second:Number, millisecond:Number):Number
按照本地时间设置分钟值，并以毫秒为单位返回新时间。
Date
  
setMonth(month:Number, day:Number):Number
按照本地时间设置月份值以及（可选）日期值，并以毫秒为单位返回新时间。
Date
 Inherited
setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void
设置循环操作动态属性的可用性。
Object
  
setSeconds(second:Number, millisecond:Number):Number
按照本地时间设置秒值，并以毫秒为单位返回新时间。
Date
  
setTime(millisecond:Number):Number
以毫秒为单位设置自 1970 年 1 月 1 日午夜以来的日期，并以毫秒为单位返回新时间。
Date
  
setUTCDate(day:Number):Number
按照通用时间 (UTC) 设置日期值，并以毫秒为单位返回新时间。
Date
  
setUTCFullYear(year:Number, month:Number, day:Number):Number
按照通用时间 (UTC) 设置年份值，并以毫秒为单位返回新时间。
Date
  
setUTCHours(hour:Number, minute:Number, second:Number, millisecond:Number):Number
按照通用时间 (UTC) 设置小时值，并以毫秒为单位返回新时间。
Date
  
setUTCMilliseconds(millisecond:Number):Number
按照通用时间 (UTC) 设置毫秒值，并以毫秒为单位返回新时间。
Date
  
setUTCMinutes(minute:Number, second:Number, millisecond:Number):Number
按照通用时间 (UTC) 设置分钟值，并以毫秒为单位返回新时间。
Date
  
setUTCMonth(month:Number, day:Number):Number
按照通用时间 (UTC) 设置月份值及（可选）日期值，并以毫秒为单位返回新时间。
Date
  
setUTCSeconds(second:Number, millisecond:Number):Number
按照通用时间 (UTC) 设置秒值以及（可选）毫秒值，并以毫秒为单位返回新时间。
Date
  
toDateString():String
仅返回星期值和日期值的字符串表示形式，而不返回时间或时区。
Date
  
toLocaleDateString():String
仅返回星期值和日期值的字符串表示形式，而不返回时间或时区。
Date
  
toLocaleString():String
按本地时间返回星期值、日期值以及时间的字符串表示形式。
Date
  
toLocaleTimeString():String
仅返回时间的字符串表示形式，而不返回星期值、日期值、年份或时区。
Date
  
toString():String
返回星期值、日期值、时间和时区的字符串表示形式。
Date
  
toTimeString():String
仅返回时间和时区的字符串表示形式，而不返回星期值和日期值。
Date
  
toUTCString():String
按照通用时间 (UTC) 返回星期值、日期值以及时间的字符串表示形式。
Date
  
UTC(year:Number, month:Number, date:Number = 1, hour:Number = 0, minute:Number = 0, second:Number = 0, millisecond:Number = 0):Number
[静态] 返回 1970 年 1 月 1 日午夜（通用时间）与参数中指定的时间之间相差的毫秒数。
Date
  
valueOf():Number
按照通用时间返回 Date 对象中自 1970 年 1 月 1 日午夜以来的毫秒数。
Date
属性详细信息
date属性
date:Number  [读写]

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照本地时间返回 Date 对象所指定的表示月中某天的值（1 到 31 之间的一个整数）。本地时间由运行 Flash Player 的操作系统确定。



实现
    AS3 function get date():Number
    AS3 function set date(value:Number):void

另请参见

getDate()
setDate()
Managing calendar dates and times
dateUTC属性 
dateUTC:Number  [读写]

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照通用时间 (UTC) 返回 Date 对象中的日期值（1 到 31 之间的一个整数）。



实现
    AS3 function get dateUTC():Number
    AS3 function set dateUTC(value:Number):void

另请参见

getUTCDate()
setUTCDate()
day属性 
day:Number  [只读 (read-only)]

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照本地时间返回该 Date 所指定的星期值（0 代表星期日，1 代表星期一，依此类推）。本地时间由运行 Flash Player 的操作系统确定。



实现
    AS3 function get day():Number

另请参见

getDay()
Managing calendar dates and times
dayUTC属性 
dayUTC:Number  [只读 (read-only)]

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照通用时间 (UTC) 返回该 Date 中的星期值（0 代表星期日，1 代表星期一，依此类推）。



实现
    AS3 function get dayUTC():Number

另请参见

getUTCDay()
fullYear属性 
fullYear:Number  [读写]

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照本地时间返回 Date 对象中的完整年份值（一个 4 位数，例如 2000）。本地时间由运行 Flash Player 的操作系统确定。



实现
    AS3 function get fullYear():Number
    AS3 function set fullYear(value:Number):void

另请参见

getFullYear()
setFullYear()
Managing calendar dates and times
fullYearUTC属性 
fullYearUTC:Number  [读写]

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照通用时间 (UTC) 返回 Date 对象中的四位数年份值。



实现
    AS3 function get fullYearUTC():Number
    AS3 function set fullYearUTC(value:Number):void

另请参见

getUTCFullYear()
setUTCFullYear()
hours属性 
hours:Number  [读写]

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照本地时间返回 Date 对象中一天的小时值（0 到 23 之间的一个整数）。本地时间由运行 Flash Player 的操作系统确定。



实现
    AS3 function get hours():Number
    AS3 function set hours(value:Number):void

另请参见

getHours()
setHours()
Managing calendar dates and times
hoursUTC属性 
hoursUTC:Number  [读写]

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照通用时间 (UTC) 返回 Date 对象中一天的小时值（0 到 23 之间的一个整数）。



实现
    AS3 function get hoursUTC():Number
    AS3 function set hoursUTC(value:Number):void

另请参见

getUTCHours()
setUTCHours()
milliseconds属性 
milliseconds:Number  [读写]

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照本地时间返回 Date 对象中的毫秒数（0 到 999 之间的一个整数）部分。本地时间由运行 Flash Player 的操作系统确定。



实现
    AS3 function get milliseconds():Number
    AS3 function set milliseconds(value:Number):void

另请参见

getMilliseconds()
setMilliseconds()
Managing calendar dates and times
millisecondsUTC属性 
millisecondsUTC:Number  [读写]

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照通用时间 (UTC) 返回 Date 对象中的毫秒值（0 到 999 之间的一个整数）部分。



实现
    AS3 function get millisecondsUTC():Number
    AS3 function set millisecondsUTC(value:Number):void

另请参见

getUTCMilliseconds()
setUTCMilliseconds()
minutes属性 
minutes:Number  [读写]

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照本地时间返回 Date 对象中的分钟值（0 到 59 之间的一个整数）部分。本地时间由运行 Flash Player 的操作系统确定。



实现
    AS3 function get minutes():Number
    AS3 function set minutes(value:Number):void

另请参见

getMinutes()
setMinutes()
Managing calendar dates and times
minutesUTC属性 
minutesUTC:Number  [读写]

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照通用时间 (UTC) 返回 Date 对象中的分钟值（0 到 59 之间的一个整数）部分。



实现
    AS3 function get minutesUTC():Number
    AS3 function set minutesUTC(value:Number):void

另请参见

getUTCMinutes()
setUTCMinutes()
month属性 
month:Number  [读写]

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照本地时间返回 Date 对象中的月份值（0 代表一月，1 代表二月，依此类推）部分。本地时间由运行 Flash Player 的操作系统确定。



实现
    AS3 function get month():Number
    AS3 function set month(value:Number):void

另请参见

getMonth()
setMonth()
Managing calendar dates and times
monthUTC属性 
monthUTC:Number  [读写]

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照通用时间 (UTC) 返回 Date 对象中的月份值（0 [一月] 到 11 [十二月]）部分。



实现
    AS3 function get monthUTC():Number
    AS3 function set monthUTC(value:Number):void

另请参见

getUTCMonth()
setUTCMonth()
seconds属性 
seconds:Number  [读写]

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照本地时间返回 Date 对象中的秒值（0 到 59 之间的一个整数）部分。本地时间由运行 Flash Player 的操作系统确定。



实现
    AS3 function get seconds():Number
    AS3 function set seconds(value:Number):void

另请参见

getSeconds()
setSeconds()
Managing calendar dates and times
secondsUTC属性 
secondsUTC:Number  [读写]

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照通用时间 (UTC) 返回 Date 对象中的秒值（0 到 59 之间的一个整数）部分。



实现
    AS3 function get secondsUTC():Number
    AS3 function set secondsUTC(value:Number):void

另请参见

getUTCSeconds()
setUTCSeconds()
time属性 
time:Number  [读写]

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

Date 对象中自 1970 年 1 月 1 日午夜（通用时间）以来的毫秒数。在比较两个或更多个 Date 对象时，可使用此方法表示某一特定时刻。



实现
    AS3 function get time():Number
    AS3 function set time(value:Number):void

另请参见

getTime()
setTime()
timezoneOffset属性 
timezoneOffset:Number  [只读 (read-only)]

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

计算机的本地时间和通用时间 (UTC) 之间的差值（以分钟为单位）。具体而言，该值即需要添加到计算机本地时间值中以与 UTC 相等的分钟数。如果计算机时间设置晚于 UTC，则该值将为负数。



实现
    AS3 function get timezoneOffset():Number

另请参见

getTimezoneOffset()
构造函数详细信息
Date()构造函数
public function Date(yearOrTimevalue:Object, month:Number, date:Number = 1, hour:Number = 0, minute:Number = 0, second:Number = 0, millisecond:Number = 0)

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

构造一个新的 Date 对象，该对象将保存指定的日期和时间。

Date() 构造函数使用最多七个参数（year、month、... millisecond）将日期和时间指定为毫秒。新构造的 Date 对象包含的日期取决于传递的参数的数目和数据类型。

如果传递一个字符串给 Date 类构造函数，则日期可以有多种格式，但必须至少包括月、日和年。例如，Feb 1 2005 是有效的，而 Feb 2005 则是无效的。下表列出了一些有效格式：

参数
yearOrTimevalue:Object — 如果指定了其它参数，则此数字表示年份（如 1965）；否则，表示时间值。如果该数字表示年份，则 0 至 99 之间的值表示 1900 年至 1999 年；否则，必须指定表示年份的所有 4 位数字。如果该数字表示时间值（未指定任何其它参数），则为 GMT 时间 1970 年 1 月 1 日 0:00:00 之前或之后的毫秒数；负值表示 GMT 时间 1970 年 1 月 1 日 0:00:00 之前 的某个时间，而正值表示该时间之后的某个时间。
 
month:Number — 0（一月）到 11（十二月）之间的一个整数。
 
date:Number (default = 1) — 1 到 31 之间的一个整数。
 
hour:Number (default = 0) — 0（午夜）到 23（晚上 11 点）之间的一个整数。
 
minute:Number (default = 0) — 0 到 59 之间的一个整数。
 
second:Number (default = 0) — 0 到 59 之间的一个整数。
 
millisecond:Number (default = 0) — 0 到 999 之间的一个整数（毫秒）。

另请参见

getMonth()
getDate()
getFullYear()
Managing calendar dates and times
方法详细信息
getDate()方法
AS3 function getDate():Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照本地时间返回 Date 对象指定的月中某天的值（1 到 31 之间的一个整数）。本地时间由运行 Flash Player 的操作系统确定。

返回
Number — Date 对象代表的月中某天的值 (1 - 31)。

另请参见

getMonth()
getFullYear()

示例

下例创建一个新的 Date 对象 someBirthday，包含参数 year (1974)、month (10 = November)、day (30)、hour (1) 和 minute (20)。然后，调用 getDate() 方法，以检索月中某天的值。 
package {
    import flash.display.Sprite;

    public class DateExample extends Sprite {

        public function DateExample() {
            var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
            trace(someBirthday);            // Sat Nov 30 01:20:00 GMT-0800 1974
            trace(someBirthday.getDate()); // 30
        }
    }
}
getDay()方法 
AS3 function getDay():Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照本地时间返回该 Date 所指定的星期值（0 代表星期日，1 代表星期一，依此类推）。本地时间由运行 Flash Player 的操作系统确定。

返回
Number — Date 对象代表的星期值的数字版本 (0 - 6)。

示例

下例创建一个新的 Array 对象 weekDayLabels，包含元素 [Sunday,Monday,Tuesday,Wednesday,Thursday,Friday,Saturday]，并创建一个新的 Date 对象 someBirthday，包含参数 year (1974)、month (10 = November)、day (30)、hour (1) 和 minute (20)。然后，两次调用 getDay() 方法，先将月中某天的值显示为 6，然后显示星期值（使用 weekDayLabels）。 

var weekDayLabels:Array = new Array("Sunday",
                    "Monday",
                    "Tuesday",
                    "Wednesday",
                    "Thursday",
                    "Friday",
                    "Saturday");

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);                       // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getDay());            // 6
trace(weekDayLabels[someBirthday.getDay()]); // Saturday
getFullYear()方法 
AS3 function getFullYear():Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照本地时间返回 Date 对象中的完整年份值（一个 4 位数，如 2000）。本地时间由运行 Flash Player 的操作系统确定。

返回
Number — Date 对象代表的完整年份值。

示例

下例创建一个新的 Date 对象 someBirthday，包含参数 year (1974)、month (10 = November)、day (30)、hour (1) 和 minute (20)。然后，调用 getFullYear() 方法，以检索四位数年份值。 

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getFullYear()); // 1974
getHours()方法 
AS3 function getHours():Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照本地时间返回 Date 对象中一天的小时值（0 到 23 之间的一个整数）。本地时间由运行 Flash Player 的操作系统确定。

返回
Number — Date 对象代表的一天中的小时值 (0 - 23)。

示例

下例创建一个新的 Date 对象 someBirthday，包含参数 year (1974)、month (10 = November)、day (30)、hour (1) 和 minute (20)。然后，调用 getHours() 和 getMinutes() 方法，以按 24 小时格式检索小时和分钟值。最后，创建一个字符串 localTime，并赋予其调用函数 getUSClockTime() 的结果，后者可依次重新调用 getHours() 和 getMinutes()，从而获得时间 03:05 PM。 

var someBirthday:Date = new Date(1974, 10, 30, 15, 5);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:5

var localTime:String = getUSClockTime(someBirthday.getHours(), someBirthday.getMinutes());
trace(localTime);    // 03:05 PM

function getUSClockTime(hrs:uint, mins:uint):String {
    var modifier:String = "PM";
    var minLabel:String = doubleDigitFormat(mins);

    if(hrs > 12) {
        hrs = hrs-12;
    } else if(hrs == 0) {
        modifier = "AM";
        hrs = 12;
    } else if(hrs < 12) {
        modifier = "AM";
    }

    return (doubleDigitFormat(hrs) + ":" + minLabel + " " + modifier);
}

function doubleDigitFormat(num:uint):String {
    if(num < 10) {
        return ("0" + num);
    }
    return num;
}
getMilliseconds()方法 
AS3 function getMilliseconds():Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照本地时间返回 Date 对象中的毫秒值（0 到 999 之间的一个整数）部分。本地时间由运行 Flash Player 的操作系统确定。

返回
Number — Date 对象中的毫秒值部分。

示例

以下示例创建一个不带参数的新 Date 对象 now。然后，调用 getMilliseconds() 方法，以检索 Date 对象 now 创建时的毫秒值。 

var now:Date = new Date();
trace(now.getMilliseconds());
getMinutes()方法 
AS3 function getMinutes():Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照本地时间返回 Date 对象中的分钟值（0 到 59 之间的一个整数）部分。本地时间由运行 Flash Player 的操作系统确定。

返回
Number — Date 对象中的分钟值部分。

示例

以下示例创建一个不带参数的新 Date 对象 now。然后，调用 getMinutes() 方法，以检索 Date 对象 now 创建时的分钟值。 

var now:Date = new Date();
trace(now);
trace(now.getMinutes());
getMonth()方法 
AS3 function getMonth():Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照本地时间返回该 Date 中的月份值（0 代表一月，1 代表二月，依此类推）部分。本地时间由运行 Flash Player 的操作系统确定。

返回
Number — Date 对象中的月份值 (0 - 11) 部分。

示例

下例创建一个新的 Array 对象 monthLabels，包含元素 January 到 December，并创建一个不带参数的新 Date 对象 now。然后，两次调用 getMonth() 方法，先返回 Date 对象 now 创建之月的月份，再返回月份名称。 

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(monthLabels[now.getMonth()]);
getSeconds()方法 
AS3 function getSeconds():Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照本地时间返回 Date 对象中的秒值（0 到 59 之间的一个整数）部分。本地时间由运行 Flash Player 的操作系统确定。

返回
Number — Date 对象中的秒值（0 到 59）部分。

示例

以下示例创建一个不带参数的新 Date 对象 now。然后，调用 getSeconds() 方法，以检索 Date 对象 now 创建时的秒值。 

var now:Date = new Date();
trace(now.getSeconds());
getTime()方法 
AS3 function getTime():Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照通用时间返回 Date 对象中自 1970 年 1 月 1 日午夜以来的毫秒数。在比较两个或更多个 Date 对象时，可使用此方法表示某一特定时刻。

返回
Number — Date 对象代表的自 1970 年 1 月 1 日以来的毫秒数。

示例

下例创建一个新的 Date 对象 mlk，包含参数 year (1929)、month (0 = January) 和 day (15)。 然后，调用 getTime() 方法，检索自 1970 年 1 月 1 日午夜以来的毫秒值，由于年份设置为 1929，因此该值为负数。 

var mlk:Date = new Date(1929, 0, 15);
trace(mlk);           // Tue Jan 15 00:00:00 GMT-0800 1929
trace(mlk.getTime()); // -1292601600000

下面的示例创建一个不带参数的新 Date 对象 now，然后使用以下 DateMath（将在下面创建）类方法从原始 Date 对象 now 创建之时起向其中添加时间：
  • addSeconds()：向 now 中添加 30 秒。
  • addMinutes()：向 now 中添加 30 分钟。
  • addHours()：向 Date 对象 now 中添加 6 小时。
  • addDays()：向 Date 对象 now 中添加 30 天。
  • addWeeks()：向 now 中添加 4 周。

var now:Date = new Date();
trace(now);
trace(DateMath.addSeconds(now, 30));
trace(DateMath.addMinutes(now, 30));
trace(DateMath.addHours(now, 6));
trace(DateMath.addDays(now, 30));
trace(DateMath.addWeeks(now, 4));

class DateMath {
    public static function addWeeks(date:Date, weeks:Number):Date {
        return addDays(date, weeks*7);
    }

    public static function addDays(date:Date, days:Number):Date {
        return addHours(date, days*24);
    }

    public static function addHours(date:Date, hrs:Number):Date {
        return addMinutes(date, hrs*60);
    }

    public static function addMinutes(date:Date, mins:Number):Date {
        return addSeconds(date, mins*60);
    }

    public static function addSeconds(date:Date, secs:Number):Date {
        var mSecs:Number = secs * 1000;
        var sum:Number = mSecs + date.getTime();
        return new Date(sum);
    }
}
注意：在执行日期计算时务必使用 getTime，因为它在闰年仍可继续工作，而不需要类似以下伪代码一样使用一串 if 逻辑： 
 function addMonths(num:Number):void {
 	currentMonth = currentMonth + num;
 	if(currentMonth > 12) {
 		currentYear++;
 		currentMonth = currentMonth - 12;
 	}
 }
getTimezoneOffset()方法 
AS3 function getTimezoneOffset():Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

以分钟为单位，返回计算机的本地时间和通用时间 (UTC) 之间的差值。

返回
Number — 需要添加到计算机本地时间值中以与 UTC 相等的分钟数。如果计算机时间设置晚于 UTC，则返回值将为负数。

示例

以下示例创建一个不带参数的新 Date 对象 now。然后，调用 getTimezoneOffset() 方法，以检索 now 创建时与通用时间之间的差值（以分钟为单位）。然后将结果除以 60，从而将时区偏移转换为小时。 

var date:Date = new Date();
trace(date.getTimezoneOffset() / 60);
getUTCDate()方法 
AS3 function getUTCDate():Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照通用时间 (UTC) 返回 Date 对象中表示月中某天的值（1 到 31 之间的一个整数）。

返回
Number — Date 对象代表的 UTC 时间月中某天的值（1 到 31）。

另请参见

getDate()

示例

下例创建一个新的 Date 对象 someBirthday，包含参数 year (1974)、month (10 = November)、day (30)、hour (1) 和 minute (20)。然后，调用 getUTCDate() 方法，以根据 UTC 检索月中某天的值。 

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);             // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDate()); // 30
getUTCDay()方法 
AS3 function getUTCDay():Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照通用时间 (UTC) 返回该 Date 中表示星期的值（0 代表星期日，1 代表星期一，依此类推）。

返回
Number — Date 对象代表的 UTC 时间的星期值（0 到 6）。

另请参见

getDay()

示例

下例创建一个新的 Array 对象 weekDayLabels，包含元素 [Sunday,Monday,Tuesday,Wednesday,Thursday,Friday,Saturday]，并创建一个新的 Date 对象 someBirthday，包含参数 year (1974)、month (10 = November)、day (30)、hour (1) 和 minute (20)。然后，两次调用 getUTCDay() 方法，按照 UTC 先将月中某天的值显示为 6，然后显示星期值（使用 weekDayLabels）。 

var weekDayLabels:Array = new Array("Sunday",
                    "Monday",
                    "Tuesday",
                    "Wednesday",
                    "Thursday",
                    "Friday",
                    "Saturday");

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDay()); // 6
trace(weekDayLabels[someBirthday.getUTCDay()]); // Saturday
getUTCFullYear()方法 
AS3 function getUTCFullYear():Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照通用时间 (UTC) 返回 Date 对象中的四位数年份值。

返回
Number — Date 对象代表的 UTC 时间的四位数年份值。

另请参见

getFullYear()

示例

下例创建一个新的 Date 对象 someBirthday，包含参数 year (1974)、month (10 = November)、day (30)、hour (1) 和 minute (20)。然后，调用 getUTCFullYear() 方法，以根据 UTC 检索四位数年份值。 

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);                 // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCFullYear()); // 1974
getUTCHours()方法 
AS3 function getUTCHours():Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照通用时间 (UTC) 返回 Date 对象中一天的小时值（0 到 23 之间的一个整数）。

返回
Number — Date 对象代表的一天中的 UTC 小时值（0 到 23）。

另请参见

getHours()

示例

下例创建一个新的 Date 对象 someBirthday，包含参数 year (1974)、month (10 = November)、day (30)、hour (1) 和 minute (20)。然后，调用 getHours() 和 getMinutes() 方法，以按 24 小时格式检索小时和分钟值。最后，创建一个字符串 localTime，并赋予其调用函数 getUSClockTime() 的结果，后者可依次重新调用 getHours() 和 getMinutes()，从而获得时间 03:05 PM。最终，采用与 localTime 相同的方式创建了一个字符串变量 utcTime，在这种情况下，获得的结果是一样的。 

var someBirthday:Date = new Date(1974, 10, 30, 15, 5);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:5

var localTime:String = getUSClockTime(someBirthday.getHours(), someBirthday.getMinutes());
trace(localTime);    // 03:05 PM

var utcTime:String = getUSClockTime(someBirthday.getUTCHours(), someBirthday.getUTCMinutes());
trace(utcTime);      // 11:05 PM

function getUSClockTime(hrs:uint, mins:uint):String {
    var modifier:String = "PM";
    var minLabel:String = doubleDigitFormat(mins);

    if(hrs > 12) {
        hrs = hrs-12;
    } else if(hrs == 0) {
        modifier = "AM";
        hrs = 12;
    } else if(hrs < 12) {
        modifier = "AM";
    }

    return (doubleDigitFormat(hrs) + ":" + minLabel + " " + modifier);
}

function doubleDigitFormat(num:uint):String {
    if(num < 10) {
        return ("0" + num);
    }
    return num;
}
getUTCMilliseconds()方法 
AS3 function getUTCMilliseconds():Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照通用时间 (UTC) 返回 Date 对象中的毫秒值（0 到 999 之间的一个整数）部分。

返回
Number — Date 对象中的 UTC 毫秒值部分。

示例

以下示例创建一个不带参数的新 Date 对象 now。然后，调用 getUTCMilliseconds() 方法，以按照 UTC 检索 Date 对象 now 创建时的毫秒值 

var now:Date = new Date();
trace(now.getUTCMilliseconds());
getUTCMinutes()方法 
AS3 function getUTCMinutes():Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照通用时间 (UTC) 返回 Date 对象中的分钟值（0 到 59 之间的一个整数）部分。

返回
Number — Date 对象中的 UTC 分钟值部分。

示例

以下示例创建一个不带参数的新 Date 对象 now。然后，调用 getUTCMinutes() 方法，以按照 UTC 检索 Date 对象 now 创建时的分钟值 

var now:Date = new Date();
trace(now.getUTCMinutes());
getUTCMonth()方法 
AS3 function getUTCMonth():Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照通用时间 (UTC) 返回 Date 对象中的月份值（0 [一月] 到 11 [十二月]）部分。

返回
Number — Date 对象中的 UTC 月份值部分。

另请参见

getMonth()

示例

下例创建一个新的 Array 对象 monthLabels，包含元素 January 到 December，并创建一个不带参数的新 Date 对象 now。然后，两次调用 getUTCMonth() 方法，按照 UTC 先返回 Date 对象 now 创建之月的月份，再返回月份名称 

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(now.getUTCMonth());
trace(monthLabels[now.getUTCMonth()]);
getUTCSeconds()方法 
AS3 function getUTCSeconds():Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照通用时间 (UTC) 返回 Date 对象中的秒值（0 到 59 之间的一个整数）部分。

返回
Number — Date 对象中的 UTC 秒值部分。

示例

以下示例创建一个不带参数的新 Date 对象 now。然后，调用 getUTCSeconds() 方法，以按照 UTC 检索 Date 对象 now 创建时的秒值 

var now:Date = new Date();
trace(now.getUTCSeconds());
parse()方法 
public static function parse(date:String):Number

按照 UTC 将表示日期的字符串转换为一个数字，它等于自 1970 年 1 月 1 日起已经过的毫秒数。

参数

date:String — 日期的字符串表示形式，符合 Date.toString() 的输出格式。Date.toString() 输出的日期格式为： 
     Day Mon DD HH:MM:SS TZD YYYY

例如： 

     Wed Apr 12 15:30:17 GMT-0700 2006

Time Zone Designation (TZD) 的形式始终为 GMT-HHMM 或 UTC-HHMM，这表明小时和分钟偏移相对于格林尼治平均时（GMT，现也称通用时间 (UTC)）。年月日之间可用正斜杠 (/) 或空格隔开，一定不要用短划线 (-) 隔开。下面是受支持的其它格式（可以包括这些格式的部分表示形式，即，只包括月、日和年）：

     MM/DD/YYYY HH:MM:SS TZD
     HH:MM:SS TZD Day Mon/DD/YYYY 
     Mon DD YYYY HH:MM:SS TZD
     Day Mon DD HH:MM:SS TZD YYYY
     Day DD Mon HH:MM:SS TZD YYYY
     Mon/DD/YYYY HH:MM:SS TZD
     YYYY/MM/DD HH:MM:SS TZD

返回
Number — 表示按 UTC 自 1970 年 1 月 1 日起已经过的毫秒数。

另请参见

Date.toString()

示例

以下示例将一个日期字符串赋予 dateParsed 以表示 1974 年 11 月 30 日。然后，调用 Date.parse() 方法，以便将该日期转换为自 1970 年 1 月 1 日起的毫秒数。 
var dateParsed:String = "Sat Nov 30 1974";

var milliseconds:Number = Date.parse(dateParsed);
trace(milliseconds); // 155030400000
setDate()方法 
AS3 function setDate(day:Number):Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照本地时间设置月中的某天，并以毫秒为单位返回新时间。本地时间由运行 Flash Player 的操作系统确定。

参数

day:Number — 1 到 31 之间的一个整数。

返回
Number — 新时间，以毫秒为单位。

示例

下例创建一个新的 Date 对象 someBirthday，包含参数 year (1974)、month (10 = November)、day (30)、hour (1) 和 minute (20)。然后，调用 getDate() 方法，以检索月中某天的值。接着，调用 setDate()（其中的 day 参数设置为 20），然后再次调用 getDate()，以检索新设置的月中某天的值。 

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);            // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getDate()); // 30

someBirthday.setDate(20);
trace(someBirthday.getDate()); // 20
setFullYear()方法 
AS3 function setFullYear(year:Number, month:Number, day:Number):Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照本地时间设置年份值，并以毫秒为单位返回新时间。如果指定了 month 和 day 参数，则将它们设置为本地时间。本地时间由运行 Flash Player 的操作系统确定。

调用此方法不会修改 Date 的其它字段，但如果因调用该方法而导致星期值发生变化，则 Date.getUTCDay() 和 Date.getDay() 可能报告一个新值。

参数

year:Number — 指定年份的 4 位数。两位数的数字不代表四位数的年份；例如，99 不代表 1999 年，而是表示 99 年。
 
month:Number — 0（一月）到 11（十二月）之间的一个整数。
 
day:Number — 1 到 31 之间的一个数字。

返回
Number — 新时间，以毫秒为单位。

另请参见

getUTCDay()
getDay()

示例

下例创建一个新的 Date 对象 someBirthday，包含参数 year (1974)、month (10 = November)、day (30)、hour (1) 和 minute (20)。然后，调用 getFullYear() 方法，以检索四位数年份值。接着，调用 setFullYear()（其中的 year 参数设置为 2000），然后再次调用 getFullYear()，以检索新设置的年份值。 

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getFullYear()); // 1974

someBirthday.setFullYear(2000);
trace(someBirthday.getFullYear()); // 2000
setHours()方法 
AS3 function setHours(hour:Number, minute:Number, second:Number, millisecond:Number):Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照本地时间设置小时值，并以毫秒为单位返回新时间。本地时间由运行 Flash Player 的操作系统确定。

参数

hour:Number — 0（午夜）到 23（晚上 11 点）之间的一个整数。
 
minute:Number — 0 到 59 之间的一个整数。
 
second:Number — 0 到 59 之间的一个整数。
 
millisecond:Number — 0 到 999 之间的一个整数。

返回
Number — 新时间，以毫秒为单位。

示例

下例创建一个新的 Date 对象 someBirthday，包含参数 year (1974)、month (10 = November)、day (30)、hour (1) 和 minute (20)。然后，调用方法 getHours() 和 getMinutes()，以检索小时和分钟值。接着，调用 setHours()（其中的 hour 参数设置为 12），然后再次调用 getHours() 和 getMinutes()，以检索新设置的小时和分钟值。 

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:20

someBirthday.setHours(12);
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 12:20
setMilliseconds()方法 
AS3 function setMilliseconds(millisecond:Number):Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照本地时间设置毫秒值，并以毫秒为单位返回新时间。本地时间由运行 Flash Player 的操作系统确定。

参数

millisecond:Number — 0 到 999 之间的一个整数。

返回
Number — 新时间，以毫秒为单位。

示例

以下示例创建一个不带参数的新 Date 对象 now。然后，调用方法 getMilliseconds()，以检索 now 创建时的毫秒值。接下来，再创建一个新 Date 对象 before，再调用 setMilliseconds()（其中的 millisecond 参数设置为 4），并再次调用 getMilliseconds()，以检索新设置的毫秒值。 

var now:Date = new Date();
trace(now);
trace(now.getMilliseconds());

var before:Date = new Date(now.setMilliseconds(4));
trace(before);
trace(before.getMilliseconds());
setMinutes()方法 
AS3 function setMinutes(minute:Number, second:Number, millisecond:Number):Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照本地时间设置分钟值，并以毫秒为单位返回新时间。本地时间由运行 Flash Player 的操作系统确定。

参数

minute:Number — 0 到 59 之间的一个整数。
 
second:Number — 0 到 59 之间的一个整数。
 
millisecond:Number — 0 到 999 之间的一个整数。

返回
Number — 新时间，以毫秒为单位。

示例

以下示例创建一个不带参数的新 Date 对象 now。然后，调用方法 getMinutes()，以检索 now 创建时的分钟值。接下来，再创建一个新 Date 对象 before，再调用 setMinutes()（其中的 minute 参数设置为 0），并再次调用 getMinutes()，以检索新设置的分钟值。 

var now:Date = new Date();
trace(now);
trace(now.getMinutes());

var before:Date = new Date(now.setMinutes(0));
trace(before);
trace(before.getMinutes());
setMonth()方法 
AS3 function setMonth(month:Number, day:Number):Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照本地时间设置月份值以及（可选）日期值，并以毫秒为单位返回新时间。本地时间由运行 Flash Player 的操作系统确定。

参数

month:Number — 0（一月）到 11（十二月）之间的一个整数。
 
day:Number — 1 到 31 之间的一个整数。

返回
Number — 新时间，以毫秒为单位。

示例

下例创建一个新的 Array 对象 monthLabels，包含元素 January 到 December，并创建一个不带参数的新月份对象 now。然后，调用方法 getMonth()，以检索 now 创建时的月份值。接着，调用 setMonth()（其中的 month 参数设置为 0），然后再次调用 getMonth()，以检索新设置的月份值。 

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(monthLabels[now.getMonth()]);

now.setMonth(0);
trace(now.getMonth());             // 0
trace(monthLabels[now.getMonth()]); // January
setSeconds()方法 
AS3 function setSeconds(second:Number, millisecond:Number):Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照本地时间设置秒值，并以毫秒为单位返回新时间。本地时间由运行 Flash Player 的操作系统确定。

参数

second:Number — 0 到 59 之间的一个整数。
 
millisecond:Number — 0 到 999 之间的一个整数。

返回
Number — 新时间，以毫秒为单位。

示例

以下示例创建一个不带参数的新 Date 对象 now。然后，调用方法 getseconds()，以检索 now 创建时的秒值。然后，调用 setSeconds()（其中的 second 参数设置为 0），并再次调用 getSeconds()，以检索新设置的秒值。 

var now:Date = new Date();
trace(now.getSeconds());

now.setSeconds(0);
trace(now.getSeconds()); // 0
setTime()方法 
AS3 function setTime(millisecond:Number):Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

以毫秒为单位设置自 1970 年 1 月 1 日午夜以来的日期，并以毫秒为单位返回新时间。

参数

millisecond:Number — 一个整数值，其中 0 表示通用时间 (UTC) 1 月 1 日午夜。

返回
Number — 新时间，以毫秒为单位。

示例

以下示例创建一个不带参数的新 Date 对象 now。然后，调用 setTime() 方法（其中的 millisecond 参数设置为 -1292601600000），以将时间设置为 Tue Jan 15 00:00:00 GMT-0800 1929。 

var now:Date = new Date();
trace(now);

now.setTime(-1292601600000);
trace(now); // Tue Jan 15 00:00:00 GMT-0800 1929
setUTCDate()方法 
AS3 function setUTCDate(day:Number):Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照通用时间 (UTC) 设置日期值，并以毫秒为单位返回新时间。调用该方法不会修改 Date 对象的其它字段，但如果因调用该方法而导致星期值发生变化，则 Date.getUTCDay() 和 Date.getDay() 方法可能报告一个新值。

参数

day:Number — 一个数字；1 到 31 之间的一个整数。

返回
Number — 新时间，以毫秒为单位。

另请参见

getUTCDay()
getDay()

示例

下例创建一个新的 Date 对象 someBirthday，包含参数 year (1974)、month (10 = November)、day (30)、hour (1) 和 minute (20)。调用方法 getUTCDate() 并正确返回月中某天的值。接着，调用 setUTCDate()（其中的 day 参数设置为 1），并且 trace() 语句确认该日期的设置正确。 

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday); // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDate()); // 30

someBirthday.setUTCDate(1);
trace(someBirthday); // Fri Nov 1 01:20:00 GMT-0800 1974
setUTCFullYear()方法 
AS3 function setUTCFullYear(year:Number, month:Number, day:Number):Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照通用时间 (UTC) 设置年份值，并以毫秒为单位返回新时间。

另外，还可以使用该方法设置月份和月中的某一天。调用该方法不会修改其它字段，但如果因调用该方法而导致星期值发生变化，则 Date.getUTCDay() 和 Date.getDay() 方法可能报告一个新值。

参数

year:Number — 一个整数，表示以完整的四位数年份形式指定的年份，如 2000。
 
month:Number — 0（一月）到 11（十二月）之间的一个整数。
 
day:Number — 1 到 31 之间的一个整数。

返回
Number — 一个整数。

另请参见

getUTCDay()
getDay()

示例

下例创建一个新的 Date 对象 someBirthday，包含参数 year (1974)、month (10 = November)、day (30)、hour (1) 和 minute (20)。调用方法 getUTCFullYear() 并正确返回四位数年份值。接着，调用 setUTCFullYear()（其中的 year 参数设置为 1975），并且 trace() 语句确认该年份的设置正确。 

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday); // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCFullYear()); // 1974

someBirthday.setUTCFullYear(1975);
trace(someBirthday); // Thu Nov 30 01:20:00 GMT-0800 1975
setUTCHours()方法 
AS3 function setUTCHours(hour:Number, minute:Number, second:Number, millisecond:Number):Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照通用时间 (UTC) 设置小时值，并以毫秒为单位返回新时间。还可指定分钟值、秒值和毫秒值。

参数

hour:Number — 0（午夜）到 23（晚上 11 点）之间的一个整数。
 
minute:Number — 0 到 59 之间的一个整数。
 
second:Number — 0 到 59 之间的一个整数。
 
millisecond:Number — 0 到 999 之间的一个整数。

返回
Number — 新时间，以毫秒为单位。

示例

下例创建一个新的 Date 对象 someBirthday，包含参数 year (1974)、month (10 = November)、day (30)、hour (1) 和 minute (20)。然后，调用方法 getHours()、getMinutes()、getUTCHours() 和 getUTCMinutes()，以检索小时和分钟值。接着，调用 setUTCHours()（其中的 hour 参数设置为 12），然后再次调用方法 getHours()、getMinutes()、getUTCHours() 和 getUTCMinutes()，并正确显示更新的小时值。 

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes());     // 15:20
trace(someBirthday.getUTCHours() + ":" + someBirthday.getUTCMinutes()); // 23:20

someBirthday.setUTCHours(12);
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes());     // 4:20
trace(someBirthday.getUTCHours() + ":" + someBirthday.getUTCMinutes()); // 12:20
setUTCMilliseconds()方法 
AS3 function setUTCMilliseconds(millisecond:Number):Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照通用时间 (UTC) 设置毫秒值，并以毫秒为单位返回新时间。

参数

millisecond:Number — 0 到 999 之间的一个整数。

返回
Number — 新时间，以毫秒为单位。

示例

以下示例创建一个不带参数的新 Date 对象 now。然后，调用方法 getUTCMilliseconds()，以检索 now 创建时的 UTC 毫秒值。接下来，再创建一个新 Date 对象 before，再调用 setUTCMilliseconds()（其中的 millisecond 参数设置为 4），并再次调用 getUTCMilliseconds()，以检索新设置的毫秒值。 


var now:Date = new Date();
trace(now);
trace(now.getUTCMilliseconds());

var before:Date = new Date(now.setUTCMilliseconds(4));
trace(before);
trace(before.getUTCMilliseconds());
setUTCMinutes()方法 
AS3 function setUTCMinutes(minute:Number, second:Number, millisecond:Number):Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照通用时间 (UTC) 设置分钟值，并以毫秒为单位返回新时间。还可以指定秒值和毫秒值。

参数

minute:Number — 0 到 59 之间的一个整数。
 
second:Number — 0 到 59 之间的一个整数。
 
millisecond:Number — 0 到 999 之间的一个整数。

返回
Number — 新时间，以毫秒为单位。

示例

以下示例创建一个不带参数的新 Date 对象 now。然后，调用方法 getUTCMinutes()，以检索 now 创建时的 UTC 分钟值。接下来，再创建一个新 Date 对象 before，再调用 setUTCMinutes()（其中的 minute 参数设置为 0），并再次调用 getUTCMinutes()，以检索新设置的分钟值。 

var now:Date = new Date();
trace(now);
trace(now.getUTCMinutes());

var before:Date = new Date(now.setUTCMinutes(0));
trace(before);
trace(before.getUTCMinutes());
setUTCMonth()方法 
AS3 function setUTCMonth(month:Number, day:Number):Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照通用时间 (UTC) 设置月份值及（可选）日期值，并以毫秒为单位返回新时间。调用该方法不会修改其它字段，但如果因调用该方法而导致星期值发生变化，则 Date.getUTCDay() 和 Date.getDay() 方法可能报告一个新值。

参数

month:Number — 0（一月）到 11（十二月）之间的一个整数。
 
day:Number — 1 到 31 之间的一个整数。

返回
Number — 新时间，以毫秒为单位。

另请参见

getDay()

示例

下例创建一个新的 Array 对象 UTCMonthLabels，包含元素 January 到 December，并创建一个不带参数的新 UTCMonth 对象 now。然后，调用方法 getUTCMonth()，以检索 now 创建时的 UTC 月份值。接着，调用 setUTCMonth()（其中的 month 参数设置为 0），然后再次调用 getUTCMonth()，以检索新设置的月份值。 

var UTCMonthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getUTCMonth());
trace(UTCMonthLabels[now.getUTCMonth()]);

now.setUTCUTCMonth(0);
trace(now.getUTCMonth());              // 0
trace(UTCMonthLabels[now.getUTCMonth()]); // January
setUTCSeconds()方法 
AS3 function setUTCSeconds(second:Number, millisecond:Number):Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照通用时间 (UTC) 设置秒值以及（可选）毫秒值，并以毫秒为单位返回新时间。

参数

second:Number — 0 到 59 之间的一个整数。
 
millisecond:Number — 0 到 999 之间的一个整数。

返回
Number — 新时间，以毫秒为单位。

示例

以下示例创建一个不带参数的新 Date 对象 now。然后，调用方法 getUTCSeconds()，以检索 now 创建时的秒值。然后，调用 setUTCSeconds()（其中的 second 参数设置为 0），并再次调用 getUTCSeconds()，以检索新设置的秒值。 

var now:Date = new Date();
trace(now.getUTCSeconds());

now.setUTCSeconds(0);
trace(now.getUTCSeconds()); // 0
toDateString()方法 
AS3 function toDateString():String

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

仅返回星期值和日期值的字符串表示形式，而不返回时间或时区。对比下列方法：

返回
String — 仅返回星期值和日期值的 String 表示形式。

另请参见

toString()

示例

下例创建一个不带参数的新 Date 对象 now，然后调用以下方法（在 trace() 语句中）
  • toString：显示 now 创建之时 now 的所有参数。
  • toDateString()：显示 now 创建时的 day、month 和 year 参数。

var now:Date = new Date();
trace(now);
trace(now.toDateString());
toLocaleDateString()方法 
AS3 function toLocaleDateString():String

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

仅返回星期值和日期值的字符串表示形式，而不返回时间或时区。该方法返回与 Date.toDateString 相同的值。对比下列方法：

返回
String — 仅返回星期值和日期值的 String 表示形式。

另请参见

toDateString()
toTimeString()
toString()
toLocaleString()方法 
AS3 function toLocaleString():String

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按本地时间返回星期值、日期值以及时间的字符串表示形式。对比 Date.toString() 方法，该方法返回相同的信息（包括时区），且年份值列在字符串的末尾。

返回
String — Date 对象在本地时区中的字符串表示形式。
toLocaleTimeString()方法 
AS3 function toLocaleTimeString():String

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

仅返回时间的字符串表示形式，而不返回星期值、日期值、年份或时区。对比 Date.toTimeString() 方法，该方法返回时间和时区。

返回
String — 仅返回时间和时区的字符串表示形式。

另请参见

toTimeString()
toString()方法 
AS3 function toString():String

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

返回星期值、日期值、时间和时区的字符串表示形式。输出的日期格式为： 

     Day Mon Date HH:MM:SS TZD YYYY

例如：

     Wed Apr 12 15:30:17 GMT-0700 2006

返回
String — Date 对象的字符串表示形式。

示例

下面的示例创建一个不带参数的新 Date 对象 now，然后调用 toString（在 trace() 语句中），以显示 now 创建时 now 的所有参数。 


var now:Date = new Date();
trace(now);
toTimeString()方法 
AS3 function toTimeString():String

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

仅返回时间和时区的字符串表示形式，而不返回星期值和日期值。对比 Date.toDateString() 方法，该方法只返回星期值和日期值。

返回
String — 仅返回时间和时区的字符串表示形式。

另请参见

toDateString()
toUTCString()方法 
AS3 function toUTCString():String

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照通用时间 (UTC) 返回星期值、日期值以及时间的字符串表示形式。例如，对于日期 2005 年 2 月 1 日，返回的字符串表示形式为 Tue Feb 1 00:00:00 2005 UTC。

返回
String — Date 对象的字符串表示形式（采用 UTC 时间）。

另请参见

toString()
UTC()方法 
public static function UTC(year:Number, month:Number, date:Number = 1, hour:Number = 0, minute:Number = 0, second:Number = 0, millisecond:Number = 0):Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

返回 1970 年 1 月 1 日午夜（通用时间）与参数中指定的时间之间相差的毫秒数。该方法使用通用时间，而 Date 构造函数使用本地时间。

若要将一个 UTC 日期传递给 Date 类构造函数，则该方法很有用。因为 Date 类构造函数接受参数形式的毫秒偏移，所以可以使用 Date.UTC() 方法将 UTC 日期转换成相应的毫秒偏移，然后将该偏移作为参数发送给 Date 类构造函数：

参数

year:Number — 表示年份的四位数整数（例如，2000）。
 
month:Number — 0（一月）到 11（十二月）之间的一个整数。
 
date:Number (default = 1) — 1 到 31 之间的一个整数。
 
hour:Number (default = 0) — 0（午夜）到 23（晚上 11 点）之间的一个整数。
 
minute:Number (default = 0) — 0 到 59 之间的一个整数。
 
second:Number (default = 0) — 0 到 59 之间的一个整数。
 
millisecond:Number (default = 0) — 0 到 999 之间的一个整数。

返回
Number — 自 1970 年 1 月 1 日起的毫秒数以及指定日期和时间。

示例

下例创建一个新的 Date 对象 someBirthday，包含参数 year (1974)、month (10 = November)、day (30)、hour (1) 和 minute (20)，这些参数使用本地时间。然后，调用 UTC()（在 setTime() 方法中），以将上述参数重置为通用时间。 

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);
trace(someBirthday.toString());

someBirthday.setTime(Date.UTC(1974, 10, 30, 15, 20));
trace(someBirthday.toString());
valueOf()方法 
AS3 function valueOf():Number

语言版本: ActionScript 3.0
运行时版本: AIR 1.0 Flash Player 9

按照通用时间返回 Date 对象中自 1970 年 1 月 1 日午夜以来的毫秒数。

返回
Number — Date 对象表示的自 1970 年 1 月 1 日以来的毫秒数。

示例

下面的示例创建一个不带参数的新 Date 对象 now。然后，调用 getTime() 方法，以检索 now 创建时与 1970 年 1 月 1 日午夜之间的毫秒数，接着调用 valueOf()，以检索相同的内容。 


var now:Date = new Date();
trace(now.getTime());
trace(now.valueOf());
示例 如何使用示例
DateExample.as

下面的示例演示 Date() 函数的各种用法，可为下列变量赋值： 

package {
    import flash.display.Sprite;
    
    public class DateExample extends Sprite{
        public function DateExample() {
            var myDate1:Date = new Date();
            trace(myDate1); // [NOW]

            var myDate2:Date = new Date(2000, 0, 1);
            trace(myDate2); // Sat Jan 1 00:00:00 GMT-0800 2000

            var myDate3:Date = new Date(65, 2, 6, 9, 30, 15, 0);
            trace(myDate3); // Sat Mar 6 09:30:15 GMT-0800 1965

            var myDate4:Date = new Date(-14159025000);
            trace(myDate4); // Sun Jul 20 19:56:15 GMT-0700 1969
        }        
    }    
}



© 2004-2008 Adobe Systems Incorporated. All rights reserved.
Sun Dec 14 2008, 10:39 PM -08:00