斜角的角度。有效值为 0 到 360 度。默认值为 45 度。

角度值表示理论上的光源落在对象上的角度，它决定了效果相对于该对象的位置。如果 distance 属性设置为 0，则效果相对于对象没有偏移，因此 angle 属性不起作用。

水平模糊量，以像素为单位。有效值为从 0 到 255（浮点）。默认值为 4。2 的乘方值（如 2、4、8、16 和 32）经过优化，呈现速度比其它值更快。

垂直模糊量，以像素为单位。有效值为从 0 到 255（浮点）。默认值为 4。2 的乘方值（如 2、4、8、16 和 32）经过优化，呈现速度比其它值更快。

斜角的偏移距离。有效值以像素为单位（浮点）。默认值为 4。

加亮颜色的 Alpha 透明度值。该值被指定为 0 到 1 之间的标准值。例如，.25 设置透明度值为 25%。默认值为 1。

斜角的加亮颜色。有效值采用十六进制格式，0xRRGGBB。默认值为 0xFFFFFF。

应用挖空效果 (true)，这将有效地使对象的填色变为透明，并显示文档的背景颜色。默认值为 false（不应用挖空效果）。

应用滤镜的次数。默认值为 BitmapFilterQuality.LOW，与应用一次滤镜等效。值 BitmapFilterQuality.MEDIUM 两次应用滤镜；值 BitmapFilterQuality.HIGH 三次应用滤镜。滤镜的值越小，呈现速度越快。

对于大多数应用，quality 的值为低、中或高就足够了。您可以使用其它数值（最高为 15）来达到不同的效果，但是值越高，呈现速度越慢。除了增加 quality 的值，仅增加 blurX 和 blurY 属性的值通常也可以获得类似的效果，而且呈现速度更快。

您可以使用以下 BitmapFilterQuality 常数指定 quality 属性的值：

• BitmapFilterQuality.LOW
• BitmapFilterQuality.MEDIUM
• BitmapFilterQuality.HIGH

阴影颜色的 Alpha 透明度值。该值被指定为 0 到 1 之间的标准值。例如，.25 设置透明度值为 25%。默认值为 1。

斜角的阴影颜色。有效值采用十六进制格式，0xRRGGBB。默认值为 0x000000。

印记或跨页的强度。有效值为 0 到 255。该值越大，印记的颜色越深，而且斜角与背景之间的对比度也越强。默认值为 1。

斜角在对象上的位置。内斜角和外斜角被放置在内缘或外缘上；完全斜角被放置在整个对象上。有效值为 BitmapFilterType 常数：

• BitmapFilterType.INNER
• BitmapFilterType.OUTER
• BitmapFilterType.FULL

用指定参数初始化新的 BevelFilter 实例。

另请参见

返回此滤镜对象的副本。

1. 导入所需的类。
2. 声明 draw() 函数所用的三个属性，该函数绘制应用了斜角滤镜的对象。
3. 创建 BevelFilterExample() 构造函数，该函数执行以下操作：
   • 调用稍后将声明的 draw() 函数。
   • 将变量 filter 声明为 BitmapFilter 对象，并将它分配给对 getBitmapFilter() 的调用的返回值。
   • 创建一个新的 Array 对象 myFilters 并将 filter 添加到该数组，将 myFilters 分配给 BevelFilterExample 对象的 filters 属性。这将应用 myFilters 中包含的所有滤镜，在本例中仅为 filter。
4. 创建 getBitmapFilter 函数，以创建和设置滤镜的属性。
5. 创建 draw() 函数。该函数使用 Graphics 类的方法（通过 Sprite 类的 graphics 属性访问）绘制正方形。

package {
    import flash.display.Sprite;
    import flash.filters.BevelFilter;
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.BitmapFilterType;

    public class BevelFilterExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        public function BevelFilterExample() {
            draw();
            var filter:BitmapFilter = getBitmapFilter();
            var myFilters:Array = new Array();
            myFilters.push(filter);
            filters = myFilters;
        }

        private function getBitmapFilter():BitmapFilter {
            var distance:Number       = 5;
            var angleInDegrees:Number = 45;
            var highlightColor:Number = 0xFFFF00;
            var highlightAlpha:Number = 0.8;
            var shadowColor:Number    = 0x0000FF;
            var shadowAlpha:Number    = 0.8;
            var blurX:Number          = 5;
            var blurY:Number          = 5;
            var strength:Number       = 5;
            var quality:Number        = BitmapFilterQuality.HIGH;
            var type:String           = BitmapFilterType.INNER;
            var knockout:Boolean      = false;

            return new BevelFilter(distance,
                                   angleInDegrees,
                                   highlightColor,
                                   highlightAlpha,
                                   shadowColor,
                                   shadowAlpha,
                                   blurX,
                                   blurY,
                                   strength,
                                   quality,
                                   type,
                                   knockout);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}