指定一个用作按钮“按下”状态（当用户单击 hitTestState 对象时，按钮所处的状态）的可视对象的显示对象。

另请参见

布尔值，指定按钮是否处于启用状态。按钮被禁用时（enabled 属性设置为 false），该按钮虽然可见，但不能被单击。默认值为 true。如果想要禁用部分导航按钮，则此属性非常有用；例如，您可能希望禁用当前显示的页面上的某个按钮，以便禁止单击该按钮并禁止重新加载该页面。

注意：若要防止按钮上的 mouseClicks 行为，请将 enabled 和 mouseEnabled 属性设置为 false。

指定一个用作按钮的点击测试对象的显示对象。对于基本按钮，将 hitTestState 属性设置为与 overState 属性相同的显示对象。如果没有设置 hitTestState 属性，则 SimpleButton 处于非活动状态 -- 它不对鼠标和键盘事件进行响应。

另请参见

指定一个用作按钮经过状态（当鼠标位于按钮上方时，按钮所处的状态）的可视对象的显示对象。

另请参见

分配给此按钮的 SoundTransform 对象。SoundTransform 对象包含用于设置音量、平移、左扬声器指定和右扬声器指定的属性。SoundTransform 对象适用于按钮的所有状态。SoundTransform 对象仅影响嵌入的声音。

另请参见

指示属于 SimpleButton 或 MovieClip 对象的其它显示对象是否可以接收鼠标释放事件。trackAsMenu 属性允许您创建菜单。可以对任何 SimpleButton 或 MovieClip 对象设置 trackAsMenu 属性。如果不存在 trackAsMenu 属性，则默认行为是 false。

您可以随时更改 trackAsMenu 属性；修改后的按钮会立即具有新的行为。

指定一个用作按钮弹起状态（当鼠标没有位于按钮上方时，按钮所处的状态）的可视对象的显示对象。

另请参见

一个布尔值，当设置为 true 时，指示鼠标指针滑过按钮上方时是否显示手形光标。如果此属性设置为 false，则将改用箭头指针。默认值为 true。

可以随时更改 useHandCursor 属性；修改后的按钮会立即使用新的光标行为。

创建一个新的 SimpleButton 实例。可以将表示各种按钮状态的任意或全部显示对象都设置为构造函数中的参数。

1. 在 SimpleButtonExample() 构造函数中，创建一个名为 button 的 SimpleButton 类型的新 CustomSimpleButton 对象，该对象调用 CustomSimpleButton 构造函数方法。button 对象将添加到显示列表中。按钮的颜色和大小在以下步骤中确定。
2. 在 CustomSimpleButton 类中，声明一些实例属性，以后将使用这些属性控制 button 处于不同状态时的大小和背景色（正常状态为黄色，鼠标滑过时为深黄色，鼠标按下时为浅蓝色）。在 button 的所有状态下，可使用 size 属性将正方形的大小设置为 80 像素。
3. CustomSimpleButton 类的构造函数使用 ButtonDisplayState 类的四个实例设置 downState、overState、upState、hitTestState 和 useHandCursor 属性。
4. 在 ButtonDisplayState 类中，构造函数设置正方形的大小和背景色的值，并调用 draw() 方法。
5. draw() 方法使用构造函数中设置的大小和背景色根据按钮的状态重绘正方形。

package {
    import flash.display.Sprite;

    public class SimpleButtonExample extends Sprite {
        public function SimpleButtonExample() {
            var button:CustomSimpleButton = new CustomSimpleButton();
            addChild(button);
        }
    }
}

import flash.display.DisplayObject;
import flash.display.Shape;
import flash.display.SimpleButton;

class CustomSimpleButton extends SimpleButton {
    private var upColor:uint   = 0xFFCC00;
    private var overColor:uint = 0xCCFF00;
    private var downColor:uint = 0x00CCFF;
    private var size:uint      = 80;

    public function CustomSimpleButton() {
        downState      = new ButtonDisplayState(downColor, size);
        overState      = new ButtonDisplayState(overColor, size);
        upState        = new ButtonDisplayState(upColor, size);
        hitTestState   = new ButtonDisplayState(upColor, size * 2);
        hitTestState.x = -(size / 4);
        hitTestState.y = hitTestState.x;
        useHandCursor  = true;
    }
}

class ButtonDisplayState extends Shape {
    private var bgColor:uint;
    private var size:uint;

    public function ButtonDisplayState(bgColor:uint, size:uint) {
        this.bgColor = bgColor;
        this.size    = size;
        draw();
    }

    private function draw():void {
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, size, size);
        graphics.endFill();
    }
}