一个 StageAlign 类中指定舞台在 Flash Player 或浏览器中的对齐方式的值。以下是有效值：

align 属性只可用于与 Stage 所有者（主 SWF 文件）位于同一安全沙箱的对象。为避免出现这种情况，Stage 所有者可以通过调用 Security.allowDomain() 方法或 Security.alowInsecureDomain() 方法来向域的调用对象授予权限。有关详细信息，请参阅《ActionScript 3.0 编程》中的“安全性”一章。

另请参见

控制显示效果的 Flash Player 颜色校正。只有在为监视器分配了有效的 ICC 颜色配置文件（指定设备的特定颜色属性）时，颜色校正才起作用。默认情况下，Flash Player 尝试匹配其主机（通常是一个浏览器）的颜色校正。

使用 Stage.colorCorrectionSupport 属性可确定颜色校正在当前系统和默认状态中是否可用。如果可以使用颜色校正，则将假定舞台上的所有颜色都处于 sRGB 颜色空间，这是最标准的颜色空间。在颜色校正过程中未考虑输入设备的源配置文件。不应用输入颜色校正；只将舞台输出映射到主监视器的 ICC 颜色配置文件。

通常，通过激活颜色管理可获得以下好处：可预知而一致的颜色、更好的转换、准确的校对以及更有效的跨媒体输出。但是请注意，由于设备相互之间或与原始图像的色域不同，因此颜色管理无法提供完美的转换。同时，尽管有颜色管理，但仍然需要自定义配置文件或编辑的配置文件。颜色配置文件取决于浏览器、操作系统 (OS)、OS 扩展、输出设备和应用程序支持。

应用颜色校正将会降低 Flash Player 的性能。Flash Player 的颜色校正是一种文档式颜色校正，因为所有 SWF 影片都被视为带有隐式 sRGB 配置文件的文档。使用 Stage.colorCorrectionSupport 属性指示 Flash Player，在将 SWF（文档）显示到显示颜色空间时将颜色校正到最佳水平。Flash Player 只会补偿监视器之间的差异，而不会补偿输入设备（摄像头/扫描仪等）之间的差异。

三个可能的值是在 flash.display.ColorCorrection 类中具有对应常数的字符串。

• “default”：使用与主机系统相同的颜色校正。
• “on”：始终执行颜色校正。
• “off”：从不执行颜色校正。

另请参见

指定 Flash Player 当前所在的操作系统是否支持颜色校正，以及 Flash Player 是否能够读取和理解主监视器的颜色配置文件。此属性还返回主机系统（通常是浏览器）上颜色校正的默认状态。当前返回值可能是：

三个可能的值是在 flash.display.ColorCorrectionSupport 类中具有对应常数的字符串。

• “unsupported”：颜色校正不可用。
• “defaultOn”：始终执行颜色校正。
• “defaultOff”：从不执行颜色校正。

另请参见

用于指定要使用哪个显示状态的 StageDisplayState 类的值。以下是有效值：

• StageDisplayState.FULL_SCREEN 将 AIR 应用程序或 Flash Player 设置成扩展舞台以覆盖用户的整个屏幕（禁用键盘输入）。
• StageDisplayState.FULL_SCREEN_INTERACTIVE 将 AIR 应用程序设置成扩展舞台以覆盖用户的整个屏幕（允许键盘输入）。（对于在 Flash Player 的内容不适用。）
• StageDisplayState.NORMAL 将播放器设置回标准的舞台显示模式。

影片在全屏模式下的缩放行为由 scaleMode 设置确定（在 HTML 文件中使用 Stage.scaleMode 属性或 SWF 文件的 embed 标签设置进行设置）。如果将 scaleMode 属性设置为 noScale，则当应用程序过渡为全屏模式时，舞台的 width 和 height 属性将更新并引发舞台的 resize 事件。

以下限制适用于在 HTML 页内播放的 SWF 文件（而不是使用独立 Flash Player 播放的文件或不在 AIR 运行时中运行的文件）：

• 若要启用全屏模式，请将 allowFullScreen 参数添加到包含 SWF 文件的 HTML 页中的 object 和 embed 标签，同时将 allowFullScreen 设置为 "true"，如下例所示：

  <param name="allowFullScreen" value="true" />
           ...
    <embed src="example.swf" allowFullScreen="true" ... >

  HTML 页还可以使用脚本生成 SWF 嵌入标签。您需要修改脚本，以使其插入正确的 allowFullScreen 设置。Flash 和 Flex Builder 生成的 HTML 页使用 AC_FL_RunContent() 函数嵌入对 SWF 文件的引用，并且您需要添加 allowFullScreen 参数设置，如下所示：

  AC_FL_RunContent( ... "allowFullScreen", "true", ... )

• 全屏模式是在响应用户单击鼠标或按键时初始化的；在没有用户输入的情况下，影片不能更改 Stage.displayState。 在全屏模式下，Flash Player 会限制键盘输入。可接受的键包括用于终止全屏模式的快捷键和非打印键，例如箭头、空格、Shift 键和 Tab 键。用于终止全屏模式的快捷键包括 Escape（Windows、Linux 和 Mac）、Ctrl+W (Windows)、Command+W (Mac) 和 Alt+F4。

  当用户进入全屏模式时，将在影片前面显示一个 Flash Player 对话框，告诉用户已经进入了全屏模式，并可以按 Esc 键退出全屏模式。

• 从 Flash Player 9.0.115.0 开始，全屏模式在无窗口模式下的工作方式与窗口模式相同。如果将窗口模式（HTML 中的 wmode）设置为不透明无窗口 (opaque) 或透明无窗口 (transparent)，则可以启动全屏模式，但全屏窗口始终是不透明的。

对于在独立 Flash Player 或 AIR 中运行的 SWF 内容，不存在这些限制。AIR 支持允许键盘输入的交互式全屏模式。

对于以全屏模式运行的 AIR 内容，在播放视频内容时，将禁用系统屏幕保护程序和节能选项，直到该视频停止或退出全屏幕模式。

另请参见

package {
    import flash.display.Sprite;
    import flash.display.Stage;
    import flash.events.*;
    import flash.net.NetConnection;
    import flash.net.NetStream;
    import flash.media.Video;
    
    public class FullScreenExample extends Sprite
    {
        private var videoURL:String = "testVideo.flv";
        private var connection:NetConnection;
        private var stream:NetStream;
        private var video:Video;        
        
        public function FullScreenExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
            
            loaderInfo.addEventListener(Event.INIT, createMouseListener);            
        }

        private function createMouseListener(event:Event):void {
            stage.addEventListener(MouseEvent.CLICK,toggleFullScreen);
        }        
        
        private function toggleFullScreen(event:MouseEvent):void {
            switch(stage.displayState) {
                case "normal":
                    stage.displayState = "fullScreen";    
                    break;
                case "fullScreen":
                default:
                    stage.displayState = "normal";    
                    break;
            }
        }    
        
        // Video related:
        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Unable to locate video: " + videoURL);
                    break;
            }
        }
        private function connectStream():void {
            var stream:NetStream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);

            video = new Video(stage.stageWidth,stage.stageHeight);
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }
        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }            
    }
}

具有键盘焦点的交互式对象；如果没有设置焦点，或者具有焦点的对象属于调用对象无权访问的安全沙箱，则为 null。

获取并设置舞台的帧频。帧频是指每秒显示的帧数。默认情况下，频率设置为第一个加载的 SWF 文件的帧频。帧频的有效范围为每秒 0.01 到 1000 个帧。

注意：应用程序可能由于以下原因而无法支持高帧速率设置：目标平台不够快或播放器与显示设备的垂直空白时间（在 LCD 设备上通常为 60 Hz）同步。在某些情况下，如果目标平台将占用高 CPU 使用率，它可能还会选择降低最大帧率。

对于在 Adobe AIR 中运行的内容，设置一个 Stage 对象的 frameRate 属性会更改所有 Stage 对象（由不同的 NativeWindow 对象使用）的帧速率。

返回变为全屏大小时使用的显示器高度（如果立即进入该状态）。如果用户有多台显示器，则使用的显示器是此时显示大部分舞台的显示器。

注意：在检索值和变为全屏大小之间，如果用户有机会将浏览器从一台显示器移到另一台显示器，则该值可能不正确。如果在将 Stage.displayState 设置为 StageDisplayState.FULL_SCREEN 的事件处理函数中检索值，则该值是正确的。

如果将 Stage.align 设置为 StageAlign.TOP_LEFT 并将 Stage.scaleMode 设置为 StageScaleMode.NO_SCALE，则该值是显示器的像素高度并且与舞台高度相同。

另请参见

import flash.display.Sprite;
import flash.display.Stage;
import flash.display.StageDisplayState;
import flash.events.MouseEvent;
import flash.geom.Rectangle;
 
// cover the stage with a green rectangle
var greenRect:Sprite = new Sprite();
greenRect.graphics.beginFill(0x00FF00);
greenRect.graphics.drawRect(0, 0, stage.stageWidth, stage.stageHeight);
addChild(greenRect);
 
// create red square on stage, turn it into a button for going to full screen
var redSquare:Sprite = new Sprite();
redSquare.graphics.beginFill(0xFF0000);
redSquare.graphics.drawRect(0, 0, 300, 300);
redSquare.x = 50;
redSquare.y = 50;
redSquare.addEventListener(MouseEvent.CLICK, enterFullScreen);
redSquare.buttonMode = true;
addChild(redSquare);
 
function enterFullScreen(e:MouseEvent):void
{
    // we will go to full screen zoomed in on the red square
    var redSquare:Sprite = e.target as Sprite;
    var fullScreenRect:Rectangle = new Rectangle(redSquare.x, redSquare.y, redSquare.width, redSquare.height);
 
    // calculate aspect ratio of the red square
    var rectAspectRatio:Number = fullScreenRect.width / fullScreenRect.height;
 
    // calculate aspect ratio of the screen
    var screenAspectRatio:Number = stage.fullScreenWidth / stage.fullScreenHeight;
  
    // change the fullScreenRect so that it covers the entire screen, keeping it centered on the redSquare
    // try commenting out this section to see what happens if you do not fix the aspect ratio.
    if (rectAspectRatio > screenAspectRatio) {
         var newHeight:Number = fullScreenRect.width / screenAspectRatio;
         fullScreenRect.y -= ((newHeight - fullScreenRect.height) / 2);
        fullScreenRect.height = newHeight;
    } else if (rectAspectRatio < screenAspectRatio) {
        var newWidth:Number = fullScreenRect.height * screenAspectRatio;
        fullScreenRect.x -= ((newWidth - fullScreenRect.width) / 2);
        fullScreenRect.width = newWidth;
    }
 
    // go to full screen
    stage.fullScreenSourceRect = fullScreenRect;
    stage.displayState = StageDisplayState.FULL_SCREEN;
}

设置 Flash Player 以将特定的舞台区域放大到全屏模式。如果可用，Flash Player 将使用硬件进行缩放（它使用用户计算机上的图形和视频卡），通常其内容显示速度比软件缩放快。

如果将此属性设置为有效矩形并将 displayState 属性设置为全屏模式，Flash Player 将对指定区域进行缩放。ActionScript 中的实际舞台大小（以像素为单位）不会发生改变。Flash Player 对矩形大小强制规定了最小限制，以容纳标准的“按 Esc 退出全屏模式”消息。通常，此限制大约为 260 x 30 个像素，但可能会随平台和 Flash Player 版本的不同而发生变化。

仅当 Flash Player 未处于全屏模式时，才能设置此属性。若要正确使用此属性，应先设置此属性，然后将 displayState 属性设置为全屏模式，如代码示例中所示。

若要启用缩放功能，请将 fullScreenSourceRect 属性设置为矩形对象：

// valid, will enable hardware scaling
  stage.fullScreenSourceRect = new Rectangle(0,0,320,240);

若要禁用缩放功能，请在 ActionScript 3.0 中设置 fullScreenSourceRect=null，而在 ActionScript 2.0 中设置 undefined。

stage.fullScreenSourceRect = null;

最终用户还可以在“Flash Player 显示设置”中进行选择以关闭硬件缩放功能，默认情况下，将启用此功能。有关详细信息，请参阅 www.adobe.com/go/display_settings_cn。

另请参见

import flash.geom.*; 
{
  stage.fullScreenSourceRect = new Rectangle(0,0,320,240);
  stage.displayState = StageDisplayState.FULL_SCREEN;
}

package {
    import flash.display.Sprite;
    import flash.display.StageDisplayState;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;
    import flash.events.NetStatusEvent;
    import flash.events.AsyncErrorEvent;
    import flash.events.SecurityErrorEvent;
    import flash.events.MouseEvent;
    import flash.events.Event;
    import flash.geom.Rectangle;
    
    public class Stage_fullScreenSourceRectExample2 extends Sprite {
        private var videoURL:String = "testVideo1.flv";
        private var connection:NetConnection;
        private var stream:NetStream;
        private var myVideo:Video;        
        private    var savedWidth:uint;
        private    var savedHeight:uint;
 
        public function Stage_fullScreenSourceRectExample2() {
    
            connection = new NetConnection();
             connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);    
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);

            loaderInfo.addEventListener(Event.INIT, createMouseListener);            
        }

        private function createMouseListener(event:Event):void {
            stage.addEventListener(MouseEvent.CLICK, toggleFullScreen);
        }        

        private function toggleFullScreen(event:MouseEvent):void {

            if(stage.displayState == StageDisplayState.NORMAL) {
                myVideo.width = myVideo.videoWidth;
                  myVideo.height = myVideo.videoHeight;

                try {
                    stage.fullScreenSourceRect = new Rectangle(myVideo.x, myVideo.y, 
                                                           myVideo.width, myVideo.height);
                     stage.displayState = StageDisplayState.FULL_SCREEN;

                 } catch (e:SecurityError) {
                     trace ("A security error occurred while switching to full screen: " + event);
                    myVideo.width = savedWidth;
                    myVideo.height = savedHeight;
                 }

            }else {
                myVideo.width = savedWidth;
                myVideo.height = savedHeight;
                stage.displayState = StageDisplayState.NORMAL;
            }
        }    

       private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace ("Unable to locate video: " + videoURL);
                    break;
            }
        }

       private function connectStream():void {
            var stream:NetStream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);     

             myVideo = new Video();
            myVideo.attachNetStream(stream);
            stream.play(videoURL);

            savedWidth = myVideo.width;
            savedHeight = myVideo.height;

            addChild(myVideo);
        }
       
        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);    
        }
        
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            
        }            
    }
}

返回变为全屏大小时使用的显示器宽度（如果立即进入该状态）。如果用户有多台显示器，则使用的显示器是此时显示大部分舞台的显示器。

注意：在检索值和变为全屏大小之间，如果用户有机会将浏览器从一台显示器移到另一台显示器，则该值可能不正确。如果在将 Stage.displayState 设置为 StageDisplayState.FULL_SCREEN 的事件处理函数中检索值，则该值是正确的。

如果将 Stage.align 设置为 StageAlign.TOP_LEFT 并将 Stage.scaleMode 设置为 StageScaleMode.NO_SCALE，则该值是显示器的像素宽度并且与舞台宽度相同。

另请参见

import flash.display.Sprite;
import flash.display.Stage;
import flash.display.StageDisplayState;
import flash.events.MouseEvent;
import flash.geom.Rectangle;
 
// cover the stage with a green rectangle
var greenRect:Sprite = new Sprite();
greenRect.graphics.beginFill(0x00FF00);
greenRect.graphics.drawRect(0, 0, stage.stageWidth, stage.stageHeight);
addChild(greenRect);
 
// create red square on stage, turn it into a button for going to full screen
var redSquare:Sprite = new Sprite();
redSquare.graphics.beginFill(0xFF0000);
redSquare.graphics.drawRect(0, 0, 300, 300);
redSquare.x = 50;
redSquare.y = 50;
redSquare.addEventListener(MouseEvent.CLICK, enterFullScreen);
redSquare.buttonMode = true;
addChild(redSquare);
 
function enterFullScreen(e:MouseEvent):void
{
    // we will go to full screen zoomed in on the red square
    var redSquare:Sprite = e.target as Sprite;
    var fullScreenRect:Rectangle = new Rectangle(redSquare.x, redSquare.y, redSquare.width, redSquare.height);
 
    // calculate aspect ratio of the red square
    var rectAspectRatio:Number = fullScreenRect.width / fullScreenRect.height;
 
    // calculate aspect ratio of the screen
    var screenAspectRatio:Number = stage.fullScreenWidth / stage.fullScreenHeight;
  
    // change the fullScreenRect so that it covers the entire screen, keeping it centered on the redSquare
    // try commenting out this section to see what happens if you do not fix the aspect ratio.
    if (rectAspectRatio > screenAspectRatio) {
         var newHeight:Number = fullScreenRect.width / screenAspectRatio;
         fullScreenRect.y -= ((newHeight - fullScreenRect.height) / 2);
        fullScreenRect.height = newHeight;
    } else if (rectAspectRatio < screenAspectRatio) {
        var newWidth:Number = fullScreenRect.height * screenAspectRatio;
        fullScreenRect.x -= ((newWidth - fullScreenRect.width) / 2);
        fullScreenRect.width = newWidth;
    }
 
    // go to full screen
    stage.fullScreenSourceRect = fullScreenRect;
    stage.displayState = StageDisplayState.FULL_SCREEN;
}

指示显示对象的高度，以像素为单位。高度是根据显示对象内容的范围来计算的。如果您设置了 height 属性，则 scaleY 属性会相应调整，如以下代码所示：

var rect:Shape = new Shape();
    rect.graphics.beginFill(0xFF0000);
    rect.graphics.drawRect(0, 0, 100, 100);
    trace(rect.scaleY) // 1;
    rect.height = 200;
    trace(rect.scaleY) // 2;

除 TextField 和 Video 对象以外，没有内容的显示对象（如一个空的 Sprite）的高度为 0，即使您尝试将 height 设置为其它值，也是这样。

确定对象的子项是否支持鼠标。如果对象支持鼠标，则用户可以使用鼠标与其交互。默认值为 true。

当您使用 Sprite 类的实例（而不是使用 SimpleButton 类）来创建按钮时，此属性很有用。当您使用 Sprite 实例来创建按钮时，您可以选择使用 addChild() 方法添加其它 Sprite 实例来修饰按钮。此过程可能导致鼠标事件出现意外行为，因为当您期望父实例成为鼠标事件的目标对象时，作为子项添加的 Sprite 实例却可能成为目标对象。要确保父实例用作鼠标事件的目标对象，您可以将父实例的 mouseChildren 属性设置为 false。

设置此属性不会调度任何事件。您必须使用 addEventListener() 方法才能创建交互式功能。

对包含此舞台的 NativeWindow 对象的引用。

窗口表示本机操作系统的窗口，舞台表示窗口所包含的内容。此属性只对在 AIR 中运行的内容有效。在 Flash Player 中（在浏览器中运行的内容），此属性将为 null。

返回此对象的子项数目。

StageQuality 类中的一个用于指定使用哪种呈现品质的值。以下是有效值：

• StageQuality.LOW -- 低呈现品质。不消除图形的锯齿，位图不进行平滑处理。Adobe AIR 中不支持此设置。
• StageQuality.MEDIUM -- 中等呈现品质。使用 2 x 2 像素网格消除图形锯齿，但不对位图进行平滑处理。此设置适用于不包含文本的影片。Adobe AIR 中不支持此设置。
• StageQuality.HIGH -- 高呈现品质。使用 4 x 4 像素网格消除图形锯齿，如果影片是静态的，则对位图进行平滑处理。这是 Flash Player 使用的默认呈现品质设置。
• StageQuality.BEST -- 极高呈现品质。使用 4 x 4 像素网格消除图形锯齿，并且始终对位图进行平滑处理。

较高的品质设置可以使缩放的位图得到较好的呈现品质。不过，较高的品质设置从运算角度看更昂贵。尤其在呈现缩放的视频时，使用较高的品质设置可以降低帧速率。

对于在 Adobe AIR 中运行的内容，可以将 quality 设置为 StageQuality.BEST 或 StageQuality.HIGH（默认值为 StageQuality.HIGH）。试图将其设置为其他值没有任何效果（且该属性保持不变）。

对于在 Adobe AIR 中运行的内容，设置一个 Stage 对象的 quality 属性会更改所有 Stage 对象（由不同的 NativeWindow 对象使用）的呈现品质。

另请参见

一个 StageScaleMode 类中指定要使用哪种缩放模式的值。以下是有效值：

• StageScaleMode.EXACT_FIT -- 整个应用程序在指定区域中可见，但不尝试保持原始高宽比。可能会发生扭曲，应用程序可能会拉伸或压缩显示。
• StageScaleMode.SHOW_ALL -- 整个应用程序在指定区域中可见，且不发生扭曲，同时保持应用程序的原始高宽比。应用程序的两侧可能会显示边框。
• StageScaleMode.NO_BORDER -- 整个应用程序填满指定区域，不发生扭曲，但有可能进行一些裁切，同时保持应用程序的原始高宽比。
• StageScaleMode.NO_SCALE -- 整个应用程序的大小固定，因此，即使播放器窗口的大小更改，它也会保持不变。如果播放器窗口比内容小，则可能进行一些裁切。

另请参见

指定显示或隐藏 Flash Player 上下文菜单中的默认项。

如果将 showDefaultContextMenu 属性设置为 true（默认设置），则会显示所有上下文菜单项。如果将 showDefaultContextMenu 属性设置为 false，则只显示“设置”和“关于 Adobe Flash Player”菜单项。

指定对象在具有焦点时是否显示加亮的边框。

舞台的当前高度（以像素为单位）。

如果将 Stage.scaleMode 属性的值设置 StageScaleMode.NO_SCALE，则当用户调整该窗口的大小时，舞台内容将保持其大小，而 stageHeight 属性将发生更改以反映由 SWF 文件占用的屏幕区域的新高度大小。（在其他缩放模式中，stageHeight 属性始终反映 SWF 文件的原始高度。）您可以为 resize 事件添加事件侦听器，然后使用 Stage 类的 stageHeight 属性来确定调整大小后的 Flash Player 窗口的实际像素尺寸。使用该事件侦听器可以控制用户调整窗口大小时屏幕内容的调整方式。

注意：在承载 SWF 文件的 HTML 页上，object 和 embed 标签的 height 属性必须设置为一个百分数（比如 100%），而不是像素。如果该设置是由 JavaScript 代码生成的，则 AC_FL_RunContent() 方法的 height 参数也必须设置为百分数。此百分数应用于 stageHeight 值。

另请参见

指定舞台的当前宽度（以像素为单位）。

如果将 Stage.scaleMode 属性的值设置 StageScaleMode.NO_SCALE，则当用户调整该窗口的大小时，舞台内容将保持其定义的大小，而 stageWidth 属性将发生更改以反映由 SWF 文件占用的屏幕区域的新宽度大小。（在其他缩放模式中，stageWidth 属性始终反映 SWF 文件的原始宽度。）您可以为 resize 事件添加事件侦听器，然后使用 Stage 类的 stageWidth 属性来确定调整大小后的 Flash Player 窗口的实际像素尺寸。使用该事件侦听器可以控制用户调整窗口大小时屏幕内容的调整方式。

注意：在承载 SWF 文件的 HTML 页上，object 和 embed 标签的 width 属性必须设置为一个百分数（比如 100%），而不是像素。如果该设置是由 JavaScript 代码生成的，则 AC_FL_RunContent() 方法的 width 参数也必须设置为百分数。此百分数应用于 stageWidth 值。

另请参见

确定对象的子项是否支持 Tab 键。为对象的子项启用或禁用 Tab 切换。默认值为 true。

返回此 DisplayObjectContainer 实例的 TextSnapshot 对象。

指示显示对象的宽度，以像素为单位。宽度是根据显示对象内容的范围来计算的。如果您设置了 width 属性，则 scaleX 属性会相应调整，如以下代码所示：

var rect:Shape = new Shape();
    rect.graphics.beginFill(0xFF0000);
    rect.graphics.drawRect(0, 0, 100, 100);
    trace(rect.scaleX) // 1;
    rect.width = 200;
    trace(rect.scaleX) // 2;

除 TextField 和 Video 对象以外，没有内容的显示对象（如一个空的 Sprite）的宽度为 0，即使您尝试将 width 设置为其它值，也是这样。

将一个 DisplayObject 子实例添加到该 DisplayObjectContainer 实例中。子项将被添加到该 DisplayObjectContainer 实例中其它所有子项的前（上）面。（要将某子项添加到特定索引位置，请使用 addChildAt() 方法。）

如果添加一个已将其它显示对象容器作为父项的子对象，则会从其它显示对象容器的子列表中删除该对象。

参数

另请参见

将一个 DisplayObject 子实例添加到该 DisplayObjectContainer 实例中。该子项将被添加到指定的索引位置。索引为 0 表示该 DisplayObjectContainer 对象的显示列表的后（底）部。

例如，下例在索引位置 0、2、1 处分别显示 a、b、c 三个显示对象：

如果添加一个已将其它显示对象容器作为父项的子对象，则会从其它显示对象容器的子列表中删除该对象。

参数

另请参见

使用 EventDispatcher 对象注册事件侦听器对象，以使侦听器能够接收事件通知。可以为特定类型的事件、阶段和优先级在显示列表的所有节点上注册事件侦听器。

AIR 运行时中的 JavaScript 代码使用此方法注册 AIR API 定义的事件的事件侦听器。对于其它 JavaScript 事件（如 DOM body 对象的 onload 事件），您可以像对浏览器中运行的内容一样使用标准事件处理技术。

成功注册一个事件侦听器后，无法通过额外调用 addEventListener() 来更改其优先级。要更改侦听器的优先级，必须首先调用 removeListener()。然后，可以使用新的优先级再次注册该侦听器。

请记住，注册该侦听器后，如果继续调用具有不同 type 或 useCapture 值的 addEventListener()，则会创建单独的侦听器注册。例如，如果首先注册 useCapture 设置为 true 的侦听器，则该侦听器只在捕获阶段进行侦听。如果使用同一个侦听器对象再次调用 addEventListener()，并将 useCapture 设置为 false，那么便会拥有两个单独的侦听器：一个在捕获阶段进行侦听，另一个在目标和冒泡阶段进行侦听。

不能只为目标阶段或冒泡阶段注册事件侦听器。这些阶段在注册期间是成对出现的，因为冒泡阶段只适用于目标节点的始祖。

如果不再需要某个事件侦听器，可调用 removeEventListener() 删除它，否则会产生内存问题。由于垃圾回收器不会删除仍包含引用的对象，因此不会从内存中自动删除使用已注册事件侦听器的对象。

复制 EventDispatcher 实例时并不复制其中附加的事件侦听器。（如果新近创建的节点需要一个事件侦听器，必须在创建该节点后附加该侦听器。） 但是，如果移动 EventDispatcher 实例，则其中附加的事件侦听器也会随之移动。

如果在正在处理事件的节点上注册事件侦听器，则不会在当前阶段触发事件侦听器，但会在事件流的稍后阶段触发，如冒泡阶段。

如果从正在处理事件的节点中删除事件侦听器，则该事件侦听器仍由当前操作触发。删除事件侦听器后，决不会再次调用该事件侦听器（除非再次注册以备将来处理）。

参数

function(evt:Event):void

另请参见

将键盘焦点设置为由 objectToFocus 指定的交互式对象，焦点方向由 direction 参数指定。

焦点方向的概念必须由应用程序（或应用程序框架）来定义。虽然可以使用其他可用的属性来确定排序原则，但交互式对象并不存在固有的焦点排序。例如，您可以按照交互式对象在舞台上或在显示列表中的位置对这些对象进行排序。调用 assignFocus() 等效于设置 Stage.focus 属性，但它还具有另外的功能，可以指示设置焦点时所使用的方向。

在接收焦点时，objectToFocus 将调度 focusIn 事件。FocusEvent 对象的 direction 属性将报告 direction 参数的设置。

如果将 HTMLLoader 对象赋予 objectToFocus 参数，则 HTMLLoader 对象会根据 direction 参数值在 HTML DOM 中选择适当的可获得焦点对象。如果该参数值为 FocusDirection.BOTTOM，则 HTML DOM 中位于读取顺序末尾的可获得焦点对象将获得焦点。如果该参数值为 FocusDirection.TOP，则 HTML DOM 中位于读取顺序开头的可获得焦点对象将获得焦点。如果该参数值为 NONE，则 HTMLLoader 对象会在不更改其当前已设置焦点元素的情况下获得焦点。

参数

另请参见

将事件调度到事件流中。事件目标是对其调用 dispatchEvent() 方法的 EventDispatcher 对象。

参数

检查 EventDispatcher 对象是否为特定事件类型注册了任何侦听器。这样，您就可以确定 EventDispatcher 对象在事件流层次结构中的哪个位置改变了对事件类型的处理。要确定特定事件类型是否确实触发了事件侦听器，请使用 willTrigger()。

hasEventListener() 与 willTrigger() 的区别是：hasEventListener() 只检查它所属的对象，而 willTrigger() 检查整个事件流以查找由 type 参数指定的事件。事件流适用于 SWF 内容中使用的 ActionScript 3.0 显示列表。

当从 LoaderInfo 对象调用 hasEventListener() 时，只考虑调用方可以访问的侦听器。

参数

调用 invalidate() 方法，以便在出现下一个 Flash Player 必须呈现显示列表的时机（例如，当播放头前进到一个新帧）时，向其发出提醒显示对象的信号。调用 invalidate() 方法后，在显示列表下次呈现时，Flash Player 会向每个已注册侦听 render 事件的显示对象发送一个 render 事件。每次想让 Flash Player 发送 render 事件时，都必须调用 invalidate() 方法。

render 事件使您可以在显示列表实际呈现前对其进行更改。因此，您就可以将对显示列表的更新尽可能地向后延迟。这样可以通过消除不必要的屏幕更新来提高性能。

只将 render 事件调度到与调用 stage.invalidate() 方法的代码位于同一安全域中的显示对象，或位于通过 Security.allowDomain() 方法被授予权限的安全域中的显示对象。

另请参见

确定 Stage.focus 属性是否因某些安全原因返回 null。也就是说，如果具有焦点的对象属于 SWF 文件无权访问的安全沙箱，那么 isFocusInaccessible 就会返回 true。

从 DisplayObjectContainer 的子列表中指定的 index 位置删除子 DisplayObject。将已删除子项的 parent 属性设置为 null；如果没有对该子项的任何其它引用，则将该对象作为垃圾回收。DisplayObjectContainer 中该子项之上的任何显示对象的索引位置都减去 1。

垃圾回收器重新分配未使用的内存空间。当在某处变量或对象不再被主动地引用或存储时，垃圾回收器将清理其过去占用的内存空间，并且如果不存在对该变量或对象的任何其它引用，则擦除此内存空间。

参数

更改现有子项在显示对象容器中的位置。这会影响子对象的分层。例如，下例在索引位置 0、1、2 处分别显示 a、b、c 三个显示对象：

在使用 setChildIndex() 方法并指定一个已经占用的索引位置时，唯一发生更改的位置是显示对象先前的位置和新位置之间的位置。所有其他位置将保持不变。如果将一个子项移动到比它当前的索引更低的索引处，则这两个索引之间的所有子项的索引引用都将增加 1。如果将一个子项移动到比它当前的索引更高的索引处，则这两个索引之间的所有子项的索引引用都将减小 1。例如，如果上例中的显示对象容器名为 container，则可以通过调用以下代码来交换带有 a 和 b 标记的显示对象的位置：

container.setChildIndex(container.getChildAt(1), 0);

该代码产生以下对象排列：

参数

在子级列表中两个指定的索引位置，交换子对象的 Z 轴顺序（前后顺序）。显示对象容器中所有其它子对象的索引位置保持不变。

参数

检查是否用此 EventDispatcher 对象或其任何始祖为指定事件类型注册了事件侦听器。将指定类型的事件调度给此 EventDispatcher 对象或其任一后代时，如果在事件流的任何阶段触发了事件侦听器，则此方法返回 true。

hasEventListener() 与 willTrigger() 方法的区别是：hasEventListener() 只检查它所属的对象，而 willTrigger() 方法检查整个事件流以查找由 type 参数指定的事件。事件流适用于 SWF 内容中使用的 ActionScript 3.0 显示列表。

当从 LoaderInfo 对象调用 willTrigger() 时，只考虑调用方可以访问的侦听器。

参数

当 Stage 对象进入或离开全屏模式时调度。可以通过 ActionScript、或用户调用键盘快捷键或者当前焦点离开全屏窗口来启动全屏模式的更改。

此事件具有以下属性：

当鼠标指针移出舞台区域时由 Stage 对象进行调度。

此事件具有以下属性：

当 Stage 对象的 scaleMode 属性设置为 StageScaleMode.NO_SCALE 且 SWF 文件大小经过重新调整时进行调度。

此事件具有以下属性：

1. 无论 Flash Player 窗口的大小如何，类的构造函数都会首先将 Flash 应用程序设置为固定大小，然后使用 activateHandler() 和 resizeHandler() 方法添加两个事件侦听器。
2. 用鼠标左键单击后，便可运行 activateHandler() 方法。
3. 当调整舞台大小时，便可运行 resizeHandler() 方法。

package {
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.Event;

    public class StageExample extends Sprite {

        public function StageExample() {
            stage.scaleMode = StageScaleMode.NO_SCALE;
            stage.align = StageAlign.TOP_LEFT;
            stage.addEventListener(Event.ACTIVATE, activateHandler);
            stage.addEventListener(Event.RESIZE, resizeHandler);
        }

        private function activateHandler(event:Event):void {
            trace("activateHandler: " + event);
        }

        private function resizeHandler(event:Event):void {
            trace("resizeHandler: " + event);
            trace("stageWidth: " + stage.stageWidth + " stageHeight: " + stage.stageHeight);
        }
    }
}