本地磁盘上文件的创建日期。如果未填充对象，则为获取此属性的值而执行的调用将返回 null。

另请参见

文件的 Macintosh 创建者类型，此类型仅用于 Mac OS X 之前的 Mac OS 版本中。在 Windows 或 Linux 中，此属性为 null。如果未填充 FileReference 对象，则为获得此属性的值而执行的调用将返回 null。

另请参见

成功调用 load() 方法之后代表所加载文件中的数据的 ByteArray 对象。

另请参见

文件扩展名。

文件的扩展名是最后一个句点（“.”）后面的名称部分（不包括句点）。如果文件名中没有句点，则 extension 为 null。

注意：应该使用 extension 属性来确定文件的类型，不要使用 creator 或 type 属性。应该将 creator 和 type 属性视为已不推荐使用。它们适用于 Mac OS 的早期版本。

本地磁盘上文件的上一次修改日期。如果未填充 FileReference 对象，则为获得此属性的值而执行的调用将返回 null。

另请参见

本地磁盘上的文件的名称。如果未填充 FileReference 对象（通过对 FileReference.download() 或 FileReference.browse() 的有效调用），则在尝试获取此属性的值时，Flash Player 将引发错误。

FileReference 对象的所有属性都通过调用 browse() 方法进行填充。与其它 FileReference 属性不同，如果调用 download() 方法，则在调度 select 事件时将填充 name 属性。

另请参见

本地磁盘上文件的大小（以字节为单位）。如果 size 为 0，将引发异常。

注意：在 ActionScript 3.0 的初始版本中，size 属性定义为 uint 对象，该对象支持大小达 4 GB 的文件。现在，它以 Number 对象的形式实现，以支持更大的文件。

另请参见

文件类型。

在 Windows 或 Linux 上，此属性是文件扩展名。在 Macintosh 上，此属性是由四个字符组成的文件类型，仅用于 Mac OS X 之前的 Mac OS 版本中。如果未填充 FileReference 对象，则为获取此属性的值而执行的调用将返回 null。

对于 Windows、Linux 和 Mac OS X，文件扩展名 - name 属性最后一个句点 (.) 字符后的部分character — 标识文件类型。

另请参见

创建新的 FileReference 对象。在填充后，FileReference 对象表示用户本地磁盘上的文件。

另请参见

显示一个文件浏览对话框，让用户选择要上载的文件。该对话框对于用户的操作系统来说是本机的。用户可以选择本地计算机上的文件，也可以选择其它系统上的文件，例如，通过 Windows 上的 UNC 路径选择文件。

当调用此方法并且用户成功选择文件时，会使用该文件的属性填充此 FileReference 对象的属性。以后每次调用 FileReference.browse() 方法时，FileReference 对象的属性都重置为用户在对话框中选择的文件。每次只能执行一个 browse() 或 download() 会话（因为每次只能调用一个对话框）。

使用 typeFilter 参数，可决定对话框显示哪些文件。

在 Flash Player 10 和 Flash Player 9 Update 5 中，只有响应用户事件（例如，在鼠标单击或按键事件的事件处理函数中）才能成功调用此方法。否则，调用此方法将导致 Flash Player 引发 Error 异常。

请注意，由于已向 Flash Player 中添加了新功能，因此当发布到 Flash Player 10 时，一次只可以激活下列操作中的一个操作：FileReference.browse()、FileReference.upload()、FileReference.download()、FileReference.load()、FileReference.save()。否则，Flash Player 会引发运行时错误（代码 2174）。使用 FileReference.cancel() 可停止正在进行的操作。此限制仅适用于 Flash Player 10。早期版本的 Flash Player 在同时进行多个操作时不会受到此限制的影响。

参数

另请参见

取消正在对该 FileReference 对象执行的任何上载或下载操作。调用此方法并不会调度 cancel 事件。仅在用户通过退出文件上载或下载对话框来取消操作时，才会调度该事件。

打开对话框，以允许用户从远程服务器下载文件。虽然 Flash Player 没有限制可上载或下载的文件的大小，但是播放器正式支持的上载或下载文件大小最大为 100 MB。

download() 方法首先打开一个操作系统对话框，让用户输入文件名并在本地计算机上选择用于保存文件的位置。用户选择了位置并确认下载操作时（例如，单击“保存”）后，开始从远程服务器下载。侦听器接收事件来指示下载的进度、成功或失败。为了在调用 download() 后确定对话框和下载操作的状态， 代码必须对 cancel、open、progress 和 complete 等事件进行侦听。

FileReference.upload() 和 FileReference.download() 函数是非阻塞式的。这些函数在调用它们之后即返回，而不会等待文件传输完成。此外，若 FileReference 对象离开作用域，则对该对象尚未完成的上载或下载操作将在它离开作用域后被取消。只要希望上载或下载操作继续，就应确保将 FileReference 对象保留在作用域中。

成功下载文件之后，将使用本地文件的属性填充 FileReference 对象的属性。如果下载成功，将调度 complete 事件。

每次只能执行一个 browse() 或 download() 会话（因为每次只能调用一个对话框）。

此方法支持使用 HTTP 或 HTTPS 下载任何文件类型。

无法连接到常用的保留端口。有关已阻止的端口的完整列表，请参阅《ActionScript 3.0 编程》一书的中的“限制网络 API”。

注意：如果服务器要求用户身份验证，则只有在浏览器中运行的 SWF 文件（即使用浏览器插件或 ActiveX 控件的文件）才可以提供对话框来提示用户输入用户名和密码以进行身份验证，并且只适用于下载。对于使用插件或 ActiveX 控件进行的上载操作，以及使用独立或外部播放器进行的上载和下载操作，文件传输会失败。

当在应用程序安全沙箱以外的安全沙箱的内容中使用此方法时，请考虑 Flash Player AIR 安全模型：

• 如果执行调用的 SWF 文件在不受信任的本地沙箱中，则不允许进行加载操作。
• 默认行为是拒绝沙箱之间的访问。 网站可通过添加 URL 策略文件来实现对资源的访问。
• 可以在包含 SWF 内容的 HTML 页中设置 object 和 embed 标签的 allowNetworking 参数，防止 SWF 文件使用此方法。
• 在 Flash Player 10 和 Flash Player 9 Update 5 中，只有响应用户事件（例如，在鼠标单击或按键事件的事件处理函数中）才能成功调用此方法。否则，调用此方法将导致 Flash Player 引发 Error 异常。

但在 Adobe AIR 中，应用程序安全沙箱中的内容（使用 AIR 应用程序安装的内容）不受这些安全限制的约束。

有关安全性的详细信息，请参阅以下部分：

• Developing AIR Applications（《开发 AIR 应用程序》）一书的“Getting started with Adobe AIR”（Adobe AIR 入门）一章中的“Understanding AIR Security”（了解 AIR 安全性）一节。
• Flash Player 开发人员中心主题：安全性

请注意，由于已向 Flash Player 中添加了新功能，因此当发布到 Flash Player 10 时，一次只可以激活下列操作中的一个操作：FileReference.browse()、FileReference.upload()、FileReference.download()、FileReference.load()、FileReference.save()。否则，Flash Player 会引发运行时错误（代码 2174）。使用 FileReference.cancel() 可停止正在进行的操作。此限制仅适用于 Flash Player 10。早期版本的 Flash Player 在同时进行多个操作时不会受到此限制的影响。

参数

另请参见

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;
    import flash.net.FileFilter;

    public class FileReference_download extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_download() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

开始加载用户选择的本地文件。虽然 Flash Player 没有限制可上载、下载、加载或保存的文件的大小，但其正式支持的文件大小最大为 100 MB。对于 Flash Player 中运行的内容，必须先调用 FileReference.browse() 或 FileReferenceList.browse() 方法，然后再调用 load() 方法。不过，应用程序沙箱中运行于 AIR 中的内容调用 File 对象的 load() 方法之前不必先调用 browse() 方法。（AIR File 类扩展了 FileReference 类。）

侦听器接收事件来指示加载的进度、成功或失败。尽管可以使用 FileReferenceList 对象让用户选择多个要加载的文件，但仍必须逐个加载这些文件。若要逐个加载文件，请遍历 FileReference 对象的 FileReferenceList.fileList 数组。

FileReference.upload()、FileReference.download()、FileReference.load() 和 FileReference.save() 函数均不分块。这些函数在调用之后即返回，而不会等待文件传输完成。此外，如果 FileReference 对象离开作用域，则该对象中尚未完成的任何事务将在离开作用域时被取消。只要希望上载、下载、加载或保存能继续，就应确保将 FileReference 对象保留在作用域中。

如果文件成功完成加载，则其内容将作为字节数组存储在 FileReference 对象的 data 属性中。

有以下安全事项需要注意：

• 如果执行调用的 SWF 文件在不受信任的本地沙箱中，则不允许进行加载操作。
• 默认行为是拒绝沙箱之间的访问。网站可通过添加跨域策略文件来实现对资源的访问。
• 可以在包含 内容的 HTML 页中设置 object 和 embed 标签的 allowNetworking 参数，防止 SWF 文件使用此方法。

不过，这些注意事项不适用于应用程序沙箱中的 AIR 内容。

请注意，当发布到 Flash Player 10 或 AIR 1.5 时，一次只能激活以下操作中的一项：FileReference.browse()、FileReference.upload()、FileReference.download()、FileReference.load()、FileReference.save()。否则，应用程序将引发运行时错误（代码 2174）。使用 FileReference.cancel() 可停止正在进行的操作。此限制仅适用于 Flash Player 10 和 AIR 1.5。对同时多项操作的这种限制不影响 Flash Player 或 AIR 的早期版本。

另请参见

打开一个对话框，允许用户将文件保存到本地文件系统。虽然 Flash Player 没有限制可上载、下载、加载或保存的文件的大小，但是播放器正式支持的文件大小最大为 100 MB。

save() 方法首先打开一个操作系统对话框，让用户输入文件名并在本地计算机上选择用于保存文件的位置。当用户选择了位置并确认保存操作时（例如通过单击“保存”），保存过程即会开始。侦听器接收事件来指示保存操作的进度、成功或失败。为了在调用 save() 后确定对话框和保存操作的状态，ActionScript 代码必须对 cancel、open、progress 和 complete 等事件进行侦听。

FileReference.upload()、FileReference.download()、FileReference.load() 和 FileReference.save() 函数均不分块。这些函数在调用之后即返回，而不会等待文件传输完成。此外，如果 FileReference 对象离开作用域，则该对象中尚未完成的任何事务将在离开作用域时被取消。只要希望上载、下载、加载或保存能继续，就应确保将 FileReference 对象保留在作用域中。

在成功保存文件之后，将使用本地文件的属性填充 FileReference 对象的属性。如果保存成功，将调度 complete 事件。

每次只能执行一个 browse() 或 save() 会话（因为每次只能调用一个对话框）。

在 Flash Player 中，只有在响应用户事件（例如，在鼠标单击或按键事件的事件处理函数中）时才能成功调用此方法。否则，调用此方法将导致 Flash Player 引发 Error 异常。此限制不适用于应用程序沙箱中的 AIR 内容。

参数

另请参见

开始将用户选择的文件上载到远程服务器。虽然 Flash Player 没有限制可上载或下载的文件的大小，但是播放器正式支持的上载或下载文件大小最大为 100 MB。调用此方法之前，必须先调用 FileReference.browse() 或 FileReferenceList.browse() 方法。

侦听器接收事件来指示上载的进度、成功或失败。尽管可以使用 FileReferenceList 对象让用户选择多个要上载的文件，但必须逐个上载文件。为此，需遍历由 FileReference 对象组成的 FileReferenceList.fileList 数组。

FileReference.upload() 和 FileReference.download() 函数是非阻塞式的。这些函数在调用它们之后即返回，而不会等待文件传输完成。此外，若 FileReference 对象离开作用域，则对该对象尚未完成的上载或下载操作将在它离开作用域后被取消。只要希望上载或下载操作继续，就应确保将 FileReference 对象保留在作用域中。

文件上载到在 url 参数中传递的 URL。该 URL 必须是配置为接受上载的服务器脚本。Flash Player 使用 HTTP POST 方法上载文件。处理上载的服务器脚本应收到包含下列元素的 POST 请求：

• Content-Type ，属于 multipart/form-data
• Content-Disposition，其 name 属性默认情况下设置为 "Filedata"，filename 属性设置为原始文件的名称
• 文件的二进制内容

无法连接到常用的保留端口。有关已阻止的端口的完整列表，请参阅《ActionScript 3.0 编程》一书的中的“限制网络 API”。

对于范例 POST 请求，请参阅有关 uploadDataFieldName 参数的描述。可以使用 upload() 方法向服务器发送 POST 或 GET 参数，请参阅有关 request 参数的描述。

如果 testUpload 参数为 true，并且要上载的文件大于约 10 KB，则基于 Windows 的 Flash Player 在上载实际的文件之前，会先发送不带内容的测试上载 POST 操作，以验证传输操作是否可能成功。之后，Flash Player 会再次发送 POST 操作，这时其中将包含实际的文件内容。对于小于 10 KB 的文件，Flash Player 则仅执行一次上载 POST 操作，其中包含要上载的实际文件内容。基于 Macintosh 的 Flash Player 不执行测试上载 POST 操作。

注意：如果服务器要求用户身份验证，则只有在浏览器中运行的 SWF 文件（即使用浏览器插件或 ActiveX 控件的文件）才可以提供对话框来提示用户输入用户名和密码以进行身份验证，并且只适用于下载。对于使用插件或 ActiveX 控件进行的上载操作，以及使用独立或外部播放器进行的上载和下载操作，文件传输会失败。

当在应用程序安全沙箱以外的安全沙箱的内容中使用此方法时，请考虑 Flash Player AIR 安全模型：

• 如果执行调用的 SWF 文件在不受信任的本地沙箱中，则不允许进行加载操作。
• 默认行为是拒绝沙箱之间的访问。 网站可通过添加 URL 策略文件来实现对资源的访问。
• 可以在包含 SWF 内容的 HTML 页中设置 object 和 embed 标签的 allowNetworking 参数，防止 SWF 文件使用此方法。

但在 Adobe AIR 中，application 安全沙箱中的内容（使用 AIR 应用程序安装的内容）不受这些安全限制的约束。

有关详细信息，请参阅以下部分：

• Developing AIR Applications（《开发 AIR 应用程序》）一书的“Getting started with Adobe AIR”（Adobe AIR 入门）一章中的“Understanding AIR Security”（了解 AIR 安全性）一节。
• Flash Player 开发人员中心主题：安全性

请注意，由于已向 Flash Player 中添加了新功能，因此当发布到 Flash Player 10 时，一次只可以激活下列操作中的一个操作：FileReference.browse()、FileReference.upload()、FileReference.download()、FileReference.load()、FileReference.save()。否则，Flash Player 会引发运行时错误（代码 2174）。使用 FileReference.cancel() 可停止正在进行的操作。此限制仅适用于 Flash Player 10。早期版本的 Flash Player 在同时进行多个操作时不会受到此限制的影响。

参数

Content-Type: multipart/form-data; boundary=AaB03x
    --AaB03x 
    Content-Disposition: form-data; name="Filedata"; filename="example.jpg" 
    Content-Type: application/octet-stream
    ... contents of example.jpg ... 
    --AaB03x--

另请参见

启动将文件上载到 URL 的操作，不进行任何编码。由于 upload() 方法会在 form-data 封套中对文件进行编码，因此 uploadUnencoded() 方法会在 HTTP 请求正文中按原样传递文件内容。如果要发送的数据已编码为接收服务器能够理解的格式，请使用 uploadUnencoded() 方法。uploadeUnencoded() 方法通常与 HTTP/WebDAV PUT 方法一起使用。

参数

另请参见

当用户通过文件浏览对话框取消文件上载或下载时调度。如果用户通过其它方式（关闭浏览器或停止当前应用程序）取消上载或下载，则 Flash Player 不会调度该事件。

此事件具有以下属性：

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_cancel extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_cancel() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            file.addEventListener(Event.CANCEL, cancelHandler);
            file.download(downloadURL, fileName);
        }
        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }
    }
}

当下载操作完成或上载操作生成 HTTP 状态代码 200 时调度。对于文件下载操作，在 Flash Player 或 Adobe AIR 将整个文件下载到磁盘上时调度此事件。对于文件上载操作，在 Flash Player 或 Adobe AIR 接收到 HTTP 状态代码 200（来自接收传输的服务器）之后调度此事件。

此事件具有以下属性：

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_complete extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_complete() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

另请参见

在 upload() 或 uploadUnencoded() 方法调用尝试通过 HTTP 访问数据，并且 Adobe AIR 可以检测并返回请求的状态代码时调度。

HTTPStatusEvent.HTTP_RESPONSE_STATUS 常量定义 httpResponseStatus 事件对象的 type 属性值。

此事件具有以下属性：

另请参见

当上载失败并且存在可用来描述失败的 HTTP 状态代码时调度。调度 httpStatus 事件之后，将调度 ioError 事件。

仅在上载失败时才调度 httpStatus 事件。对于在 Flash Player 中运行的内容，此事件不适用于下载失败。如果下载由于 HTTP 错误而失败，则将错误报告为 I/O 错误。

此事件具有以下属性：

另请参见

当上载或下载失败时调度。文件传输会失败的原因有：

• 当播放器正在读取、写入或传输文件时发生输入/输出错误。
• AIR 应用程序的 SWF 文件尝试将文件上载到要求身份验证（如用户名和密码）的服务器。在上载期间，Flash Player 或 Adobe AIR 不为用户提供输入密码的方法。如果 AIR 应用程序的 SWF 文件尝试将文件上载到要求身份验证的服务器，上载将失败。
• AIR 应用程序的 SWF 文件尝试在独立或外部播放器中从要求身份验证的服务器下载文件。在下载期间，独立播放器和外部播放器不提供用户用于输入密码的方法。 如果这些播放器中的 AIR 应用程序的 SWF 文件尝试从要求身份验证的服务器下载文件，下载将失败。文件下载只能在 ActiveX 控件、浏览器插件播放器和 Adobe AIR 运行时中成功。
• 传递到 upload() 方法中的 url 参数的值包含无效协议。有效协议包括 HTTP 和 HTTPS。

重要说明：只有在浏览器中运行的应用程序（即，使用浏览器插件或 ActiveX 控件的应用程序）和在 Adobe AIR 中运行的内容才可以提供对话框来提示用户输入用户名和密码以进行身份验证，并且只适用于下载。对于使用插件或 ActiveX 控件版本的 Flash Player 进行的上载操作，以及使用独立播放器或外部播放器进行的上载或下载操作，文件传输将失败。

此事件具有以下属性：

另请参见

当上载或下载操作开始时调度。

此事件具有以下属性：

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;
    import flash.net.FileFilter;

    public class FileReference_download extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_download() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

另请参见

在文件上载或下载操作期间定期调度。progress 事件在 Flash Player 将字节传输到服务器时调度，即使传输最终没有成功，也会在传输期间定期调度。要确定文件传输是否真正成功和完成以及何时真正成功和完成，需要侦听 complete 事件。

在某些情况下，接收不到 progress 事件。例如，当所传输的文件非常小或者上载或下载速度非常快时，可能就不会调度 progress 事件。

在低于 OS X 10.3 版本的 Macintosh 平台上不能确定文件上载进度。progress 事件在上载操作期间调用，但 progress 事件的 bytesLoaded 属性值为 -1，表示不能确定进度。

此事件具有以下属性：

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_progress extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_progress() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            file.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            file.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            file.addEventListener(Event.COMPLETE, completeHandler);
            file.download(downloadURL, fileName);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler: name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
        
        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }
    }
}

另请参见

当对 FileReference.upload() 或 FileReference.download() 方法的调用尝试将文件上载到服务器，或是从调用方安全沙箱外部的服务器上下载文件时进行调度。用于描述发生的特定错误的文本属性的值通常为 "securitySandboxError"。执行调用的 SWF 可能已经尝试访问其域外部的 SWF 文件，但却无权这样做。 您可以通过使用 URL 策略文件来尝试纠正此错误。

在 Adobe AIR 中，这些安全限制不适用于应用程序安全沙箱中的内容。

在 Adobe AIR 中，这些安全限制不适用于应用程序安全沙箱中的内容。

此事件具有以下属性：

另请参见

当用户从文件浏览对话框选择要上载或下载的文件时调度。（调用 FileReference.browse()、FileReferenceList.browse() 或 FileReference.download() 方法时将打开此对话框。）当用户选择文件并确认操作（例如，通过单击“确定”）时，会填充 FileReference 对象的属性。

对于在 Flash Player 内运行的内容或在 Adobe AIR 运行时中、但在应用程序安全沙箱以外运行的内容，select 事件的行为方式略有不同，具体取决于调用该事件的方法。在调用 browse() 后调度 select 事件时，Flash Player 或 AIR 应用程序能够读取 FileReference 对象的所有属性，因为用户所选的文件位于本地文件系统上。在调用 download() 后发生 select 事件时，Flash Player 或 AIR 应用程序只能读取 name 属性，因为在调度 select 事件时，文件尚未下载到本地文件系统。如果已下载了文件，则调度 complete 事件时，Flash Player 或 AIR 应用程序可以读取 FileReference 对象的所有其他属性。

此事件具有以下属性：

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_select extends Sprite {
        private var uploadURL:URLRequest;
        private var file:FileReference;

        public function FileReference_event_select() {
            uploadURL = new URLRequest();
            uploadURL.url = "http://www.[yourDomain].com/yourUploadHandlerScript.cfm";
            file = new FileReference();
            file.addEventListener(Event.SELECT, selectHandler);
            file.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            file.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            file.addEventListener(Event.COMPLETE, completeHandler);
            file.browse();
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + uploadURL.url);
            file.upload(uploadURL);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler: name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }
    }
}

成功上载然后从服务器接收数据之后调度。如果未从服务器返回数据，则不调度此事件。

此事件具有以下属性：

注意：若要运行此示例，请更改 uploadURL.url 属性以指向实际的 URL，而不是示例中虚拟的地址。URL 应指向名为 yourUploadHandlerScript.cfm 的文件，该文件位于指定 URL 的根 Web 目录下。根据您的配置，您可能还需要编译 SWF 文件，将“本地回放安全性”设置为“只访问网络”，或更新 Flash Player 的安全设置，以允许此文件网络访问。

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileFilter;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReferenceExample extends Sprite {
        private var uploadURL:URLRequest;
        private var file:FileReference;

        public function FileReferenceExample() {
            uploadURL = new URLRequest();
            uploadURL.url = "http://www.[yourDomain].com/yourUploadHandlerScript.cfm";
            file = new FileReference();
            configureListeners(file);
            file.browse(getTypes());
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
            dispatcher.addEventListener(DataEvent.UPLOAD_COMPLETE_DATA,uploadCompleteDataHandler);
        }

        private function getTypes():Array {
            var allTypes:Array = new Array(getImageTypeFilter(), getTextTypeFilter());
            return allTypes;
        }

        private function getImageTypeFilter():FileFilter {
            return new FileFilter("Images (*.jpg, *.jpeg, *.gif, *.png)", "*.jpg;*.jpeg;*.gif;*.png");
        }

        private function getTextTypeFilter():FileFilter {
            return new FileFilter("Text Files (*.txt, *.rtf)", "*.txt;*.rtf");
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function uploadCompleteDataHandler(event:DataEvent):void {
            trace("uploadCompleteData: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + uploadURL.url);
            file.upload(uploadURL);
        }
    }
}